FBAAVR6 ;WOIFO/SAB - RESEND VOUCHER BATCH MSG ;4/19/2012
;;3.5;FEE BASIS;**132**;JAN 30, 1995;Build 17
;;Per VHA Directive 2004-038, this routine should not be modified.
;
; ICRs
; #10004 EN^DIQ
; #10006 ^DIC
; #10026 ^DIR
Q
;
RESEND ; called by the FBAA RESEND VOUCHER MSG option
;
W !,"This option is used to resend a Voucher Batch message to Central"
W !,"Fee when the acknowledgement message reported an error or is"
W !,"overdue. An acknowledgement is considered overdue if it has not"
W !,"been received by the 3rd weekday after the Voucher Batch message"
W !,"was transmitted to Central Fee."
W !
W !,"The National Service Desk Austin should be contacted to determine"
W !,"the status of the voucher batch message before using this option"
W !,"for an overdue acknowledgement. If Central Fee already has the"
W !,"voucher batch message, you should request that Central Fee resend"
W !,"the acknowledgement message. If Central Fee does not have the"
W !,"voucher batch message then use this option to reprocess it.",!
;
N DA,DIC,DIR,DIRUT,DR,DTOUT,DUOUT,FBDT,FBN,FBVMAS,FBX,X,Y
;
; determine date that is 3 weekdays prior to the current date
S FBDT=$$CALCDT^FBAADD1(3,DT)
;
BT ; select batch
S DIC="^FBAA(161.7,",DIC(0)="AEQ"
D ; set screen
. N FBX1,FBX2,FBX3
. ; logic
. ; STATUS = VOUCHERED and
. ; VOUCHER MSG ACK STATUS=ERROR or
. ; VOUCHER MSG ACK STATUS=PENDING and VOUCHER MSG DATE not after FBDT
. S FBX1="I ($G(^(""ST""))=""V"")"
. S FBX2="$P($G(^(1)),""^"",3)=""E"""
. S FBX3="$P($G(^(1)),""^"",3)=""P""&($P($G(^(1)),""^"",2)'>"_FBDT_")"
. S DIC("S")=FBX1_"&("_FBX2_"!("_FBX3_"))"
D ^DIC K DIC G END:Y<0
L +^FBAA(161.7,+Y):$G(DILOCKTM,3)
I '$T W !,"Another user is editing this batch. Try again later." G BT
S FBN=+Y
S FBVMAS=$P($G(^FBAA(161.7,FBN,1)),U,3) ; voucher message ack status
;
; display batch
S DIC="^FBAA(161.7,",DA=FBN,DR="0:1;ST" W !! D EN^DIQ
;
; confirm help desk was contacted
I FBVMAS="P" D G:$D(DIRUT)!'Y END
. S DIR(0)="Y"
. S DIR("A")="Have you confirmed that Central Fee did not receive the voucher msg."
. W !
. D ^DIR K DIR
. I 'Y W !,"Please contact the National Service Desk Austin to determine",!,"if Central Fee received the voucher message."
;
; confirm
S DIR(0)="Y",DIR("B")="NO"
S DIR("A")="Are you sure you want to resend the voucher batch message"
D ^DIR K DIR G:$D(DIRUT)!'Y END
;
; generate voucher batch message
S FBX=$$VBMSG^FBAAVR5(FBN)
I FBX W !,"Voucher Batch message # "_FBX_" sent to Central Fee."
I 'FBX D G END
. W !,"Error occurred during creation of voucher batch message."
. W !," ",$P(FBX,U,2)
;
; display batch
S DIC="^FBAA(161.7,",DA=FBN,DR="0:1;ST" W !! D EN^DIQ
;
END ;
I $G(FBN) L -^FBAA(161.7,FBN)
Q
;
;FBAAVR6
--- Routine Detail --- with STRUCTURED ROUTINE LISTING ---[H[J[2J[HFBAAVR6 2847 printed Oct 16, 2024@17:58:07 Page 2
FBAAVR6 ;WOIFO/SAB - RESEND VOUCHER BATCH MSG ;4/19/2012
+1 ;;3.5;FEE BASIS;**132**;JAN 30, 1995;Build 17
+2 ;;Per VHA Directive 2004-038, this routine should not be modified.
+3 ;
+4 ; ICRs
+5 ; #10004 EN^DIQ
+6 ; #10006 ^DIC
+7 ; #10026 ^DIR
+8 QUIT
+9 ;
RESEND ; called by the FBAA RESEND VOUCHER MSG option
+1 ;
+2 WRITE !,"This option is used to resend a Voucher Batch message to Central"
+3 WRITE !,"Fee when the acknowledgement message reported an error or is"
+4 WRITE !,"overdue. An acknowledgement is considered overdue if it has not"
+5 WRITE !,"been received by the 3rd weekday after the Voucher Batch message"
+6 WRITE !,"was transmitted to Central Fee."
+7 WRITE !
+8 WRITE !,"The National Service Desk Austin should be contacted to determine"
+9 WRITE !,"the status of the voucher batch message before using this option"
+10 WRITE !,"for an overdue acknowledgement. If Central Fee already has the"
+11 WRITE !,"voucher batch message, you should request that Central Fee resend"
+12 WRITE !,"the acknowledgement message. If Central Fee does not have the"
+13 WRITE !,"voucher batch message then use this option to reprocess it.",!
+14 ;
+15 NEW DA,DIC,DIR,DIRUT,DR,DTOUT,DUOUT,FBDT,FBN,FBVMAS,FBX,X,Y
+16 ;
+17 ; determine date that is 3 weekdays prior to the current date
+18 SET FBDT=$$CALCDT^FBAADD1(3,DT)
+19 ;
BT ; select batch
+1 SET DIC="^FBAA(161.7,"
SET DIC(0)="AEQ"
+2 ; set screen
Begin DoDot:1
+3 NEW FBX1,FBX2,FBX3
+4 ; logic
+5 ; STATUS = VOUCHERED and
+6 ; VOUCHER MSG ACK STATUS=ERROR or
+7 ; VOUCHER MSG ACK STATUS=PENDING and VOUCHER MSG DATE not after FBDT
+8 SET FBX1="I ($G(^(""ST""))=""V"")"
+9 SET FBX2="$P($G(^(1)),""^"",3)=""E"""
+10 SET FBX3="$P($G(^(1)),""^"",3)=""P""&($P($G(^(1)),""^"",2)'>"_FBDT_")"
+11 SET DIC("S")=FBX1_"&("_FBX2_"!("_FBX3_"))"
End DoDot:1
+12 DO ^DIC
KILL DIC
if Y<0
GOTO END
+13 LOCK +^FBAA(161.7,+Y):$GET(DILOCKTM,3)
+14 IF '$TEST
WRITE !,"Another user is editing this batch. Try again later."
GOTO BT
+15 SET FBN=+Y
+16 ; voucher message ack status
SET FBVMAS=$PIECE($GET(^FBAA(161.7,FBN,1)),U,3)
+17 ;
+18 ; display batch
+19 SET DIC="^FBAA(161.7,"
SET DA=FBN
SET DR="0:1;ST"
WRITE !!
DO EN^DIQ
+20 ;
+21 ; confirm help desk was contacted
+22 IF FBVMAS="P"
Begin DoDot:1
+23 SET DIR(0)="Y"
+24 SET DIR("A")="Have you confirmed that Central Fee did not receive the voucher msg."
+25 WRITE !
+26 DO ^DIR
KILL DIR
+27 IF 'Y
WRITE !,"Please contact the National Service Desk Austin to determine",!,"if Central Fee received the voucher message."
End DoDot:1
if $DATA(DIRUT)!'Y
GOTO END
+28 ;
+29 ; confirm
+30 SET DIR(0)="Y"
SET DIR("B")="NO"
+31 SET DIR("A")="Are you sure you want to resend the voucher batch message"
+32 DO ^DIR
KILL DIR
if $DATA(DIRUT)!'Y
GOTO END
+33 ;
+34 ; generate voucher batch message
+35 SET FBX=$$VBMSG^FBAAVR5(FBN)
+36 IF FBX
WRITE !,"Voucher Batch message # "_FBX_" sent to Central Fee."
+37 IF 'FBX
Begin DoDot:1
+38 WRITE !,"Error occurred during creation of voucher batch message."
+39 WRITE !," ",$PIECE(FBX,U,2)
End DoDot:1
GOTO END
+40 ;
+41 ; display batch
+42 SET DIC="^FBAA(161.7,"
SET DA=FBN
SET DR="0:1;ST"
WRITE !!
DO EN^DIQ
+43 ;
END ;
+1 IF $GET(FBN)
LOCK -^FBAA(161.7,FBN)
+2 QUIT
+3 ;
+4 ;FBAAVR6
