Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: FBUCLET2

FBUCLET2.m

Go to the documentation of this file. 
  1. FBUCLET2 ;WOIFO/SAB - UNAUTHORIZED CLAIM LETTER (continued) ;08/15/02
  1.  ;;3.5;FEE BASIS;**38,46,69**;JAN 30, 1995
  1.  ;;Per VHA Directive 10-93-142, this routine should not be modified.
  1.  Q
  1. AUTHPR ;print authorized dates and approved amounts on disposition letter
  1.  ;INPUT:  FBDA = ien of unauthorized claim, file 162.7
  1.  ;        FBORDER = (optional) order number of status
  1.  ;        FBUCA = current (after) zero node of unauthorized claim (162.7)
  1.  ;        FBUC = unauthorized claim node in parameter file
  1.  ;        FBCC = flag, true if CC address should print at bottom of page
  1.  ;        FBCCI = # used to determine where CC address prints
  1.  ;OUTPUT: FBTAMT = total amount approved
  1.  ;        FBCC value may be changed
  1.  N DA,FBAMT,FBCPT,FBDOS,FBFILE,FBIENS,FBMOD,FBMODLE,FBSC,FBSCA
  1.  N FBSCCOL,FBUCPAY,FBX,FBY,FBACRR,FBADJLR,FBFPPSC,FBSCID,FBFPPSL,FBJ
  1.  ;
  1.  ; get list of payments for the claim
  1.  S FBX=$$PAYST^FBUCUTL(FBDA,"FBUCPAY")
  1.  ; get fpps claim id
  1.  S FBFPPSC=$P($G(^FB583(FBDA,5)),U)
  1.  S FBSCID=""
  1.  ;
  1.  ; loop thru payments to get total amount approved and suspend code list
  1.  S FBTAMT=0
  1.  F FBFILE=162.03,162.11,162.5 D
  1.  . S FBIENS="" F  S FBIENS=$O(FBUCPAY(FBDA,FBFILE,FBIENS)) Q:FBIENS=""  D
  1.  . . I FBFILE=162.03 D
  1.  . . . S FBAMT=$$GET1^DIQ(FBFILE,FBIENS,2)
  1.  . . . Q:FBSCID]""
  1.  . . . S FBSCID=$$GET1^DIQ(FBFILE,FBIENS,49)
  1.  . . I FBFILE=162.11 D
  1.  . . . S FBAMT=$$GET1^DIQ(FBFILE,FBIENS,6.5)
  1.  . . I FBFILE=162.5 D
  1.  . . . S FBAMT=$$GET1^DIQ(FBFILE,FBIENS,8)
  1.  . . . Q:FBSCID]""
  1.  . . . S FBSCID=$$GET1^DIQ(FBFILE,FBIENS,55)  ; patient control number
  1.  . . S FBTAMT=FBTAMT+FBAMT
  1.  ;
  1.  ; print authorized dates and total amount
  1.  I $Y+$S(FBCC:FBCCI,1:8)>IOSL D PAGE^FBUCLET1
  1.  W !?8,"Authorized from: ",$$FMTE^XLFDT($P(FBUCA,U,13))
  1.  W "  Authorized to: ",$$FMTE^XLFDT($P(FBUCA,U,14))
  1.  W !?8,"Amount approved:  " W:FBTAMT "$",$FN(FBTAMT,",",2)
  1.  W "  Itemized list follows:"
  1.  ;
  1.  ; print header and detail lines for civil hospital payments
  1.  I $D(FBUCPAY(FBDA,162.5)) D
  1.  . I $Y+$S(FBCC:FBCCI,1:7)>IOSL D PAGE^FBUCLET1
  1.  . W !!?8,"Patient Control Number: ",FBSCID
  1.  . I $Y+$S(FBCC:FBCCI,1:11)>IOSL D PAGE^FBUCLET1
  1.  . D CHDHD
  1.  . S FBIENS=""
  1.  . F  S FBIENS=$O(FBUCPAY(FBDA,162.5,FBIENS)) Q:FBIENS=""  D CHD
  1.  ;
  1.  ; print header and detail lines for outpatient/ancillary payments
  1.  I $D(FBUCPAY(FBDA,162.03)) D
  1.  . I $Y+$S(FBCC:FBCCI,1:7)>IOSL D PAGE^FBUCLET1
  1.  . W !!?8,"Patient Account Number: ",FBSCID
  1.  . I $Y+$S(FBCC:FBCCI,1:11)>IOSL D PAGE^FBUCLET1
  1.  . D ODHD
  1.  . S FBIENS=""
  1.  . F  S FBIENS=$O(FBUCPAY(FBDA,162.03,FBIENS)) Q:FBIENS=""  D OD
  1.  ;
  1.  ; print header and detail lines for pharmacy payments
  1.  I $D(FBUCPAY(FBDA,162.11)) D
  1.  . I $Y+$S(FBCC:FBCCI,1:11)>IOSL D PAGE^FBUCLET1
  1.  . D PDHD
  1.  . S FBIENS=""
  1.  . F  S FBIENS=$O(FBUCPAY(FBDA,162.11,FBIENS)) Q:FBIENS=""  D PD
  1.  ;
  1.  ;set FBSCCOL flag to indicate if the suspend code column should be used
  1.  ;    = 1 or 0 (1 if there are any suspend codes beside "4 Other")
  1.  S FBSCCOL=0
  1.  S FBSC="" F  S FBSC=$O(FBSCA(FBSC)) Q:FBSC=""  I FBSC'=4 S FBSCCOL=1 Q
  1.  ;
  1.  ; print relevant suspend code descriptions 
  1.  I FBSCCOL D
  1.  . N FBGL,FBLBL
  1.  . I $Y+$S(FBCC:FBCCI,1:10)>IOSL D PAGE^FBUCLET1
  1.  . W !!?8,"*Reason(s) for Suspension"
  1.  . S FBSC="" F  S FBSC=$O(FBSCA(FBSC)) Q:FBSC=""  D
  1.  . . I FBSC="4" D  Q
  1.  . . . W !?8,"(4) Other. Specific reason immediately follows item."
  1.  . . ; print description of suspend code from file when not "Other"
  1.  . . S FBGL="^FBAA(161.27,"
  1.  . . S FBLBL="("_FBSC_") "
  1.  . . S DA=$O(^FBAA(161.27,"B",FBSC,0))
  1.  . . I $Y+$S(FBCC:FBCCI,1:9)>IOSL D PAGE^FBUCLET1
  1.  . . D TXT^FBUCUTL2(FBGL,DA,1,"WC69I8",1,1,.FBCC,FBCCI,FBLBL)
  1.  ;
  1.  W !
  1.  D ACT:$D(FBACRR) K FBACRR
  1.  Q
  1.  ;
  1. ACT ; print table of adjustment reason descriptions
  1.  ; Input
  1.  ;    FBACRR( - required, array
  1.  ;    FBACRR(FBADJRE)=""
  1.  ;    where FBADJRE = adjustment reason code, external value
  1.  N FBADJRE,FBI,X,FBACT
  1.  I $Y+$S(FBCC:FBCCI,1:10)>IOSL D PAGE^FBUCLET1
  1.  W !,?8,"*Adjustment Code Text:"
  1.  S FBADJRE="" F  S FBADJRE=$O(FBACRR(FBADJRE)) Q:FBADJRE=""  D
  1.  . ; get description of code in FBACT
  1.  . I $$AR^FBUTL1(,FBADJRE,,"FBACT")<0 Q  ; quit if error
  1.  . ; print code and description
  1.  . K ^UTILITY($J,"W")
  1.  . S DIWL=1,DIWF="WC79I8"
  1.  . ; include code in output
  1.  . I $Y+$S(FBCC:FBCCI,1:9)>IOSL D PAGE^FBUCLET1
  1.  . S X=$$LJ^XLFSTR("("_FBADJRE_")",6," ") D ^DIWP
  1.  . S DIWF="WC79I14"
  1.  . ; include description in output
  1.  . S FBI=0 F  S FBI=$O(FBACT(FBI)) Q:FBI=""  S X=FBACT(FBI) I X]"" D ^DIWP
  1.  . D ^DIWW
  1.  Q
  1.  ;
  1. CHDHD ; civil hospital payment detail header
  1.  W !!?8,"Admission Date",?24,"Discharge Date"
  1.  W ?40,"Amt Claimed",?53,"Amt Approved"
  1.  W ?67,"Adj Code*"
  1.  W !?8,"--------------",?24,"--------------"
  1.  W ?40,"-----------",?53,"------------"
  1.  W ?67,"--------"
  1.  Q
  1. CHD ; civil hospital payment detail
  1.  S FBSC=""
  1.  S DA=$P(FBIENS,",")
  1.  S FBY=$G(^FBAAI(DA,0))
  1.  S FBFPPSL=$P($G(^FBAAI(DA,3)),U,2) ; fpps line item
  1.  S FBADJLR=$P($$ADJLRA^FBCHFA(DA_","),U)
  1.  S:FBADJLR]"" FBACRR(FBADJLR)=""
  1.  I $Y+$S(FBCC:FBCCI,1:10)>IOSL D PAGE^FBUCLET1,CHDHD
  1.  W !!?8,$$FMTE^XLFDT($P(FBY,U,6)),?24,$$FMTE^XLFDT($P(FBY,U,7))
  1.  W ?40,$J("$"_$FN($P(FBY,U,8),",",2),11)
  1.  W ?53,$J("$"_$FN($P(FBY,U,9),",",2),12)
  1.  S:FBADJLR="" FBSC=$$GET1^DIQ(162.5,FBIENS,10)
  1.  S:FBSC]"" FBSCA(FBSC)=""
  1.  W ?70,$S(FBADJLR]"":FBADJLR,1:FBSC)
  1.  I FBFPPSC]"" W !,?8,"FPPS Claim ID: ",FBFPPSC,?36,"FPPS Line Item: ",FBFPPSL
  1.  ; if "Other" suspend code then print description
  1.  I FBSC="4" D
  1.  . N FBGL,FBLBL
  1.  . S FBGL="^FBAAI("
  1.  . S FBLBL="Reason for Suspension: "
  1.  . D:$Y+$S(FBCC:FBCCI,1:9)>IOSL PAGE^FBUCLET1
  1.  . D TXT^FBUCUTL2(FBGL,DA,1,"WC69I10",1,1,.FBCC,FBCCI,FBLBL)
  1.  Q
  1. ODHD ; outpatient/ancillary payment header
  1.  W !!?8,"Service Date",?22,"CPT-MOD"
  1.  W ?40,"Amt Claimed",?53,"Amt Approved"
  1.  W ?67,"Adj Code*"
  1.  W !?8,"------------",?22,"--------"
  1.  W ?40,"-----------",?53,"------------"
  1.  W ?67,"--------"
  1.  Q
  1.  ;
  1. OD ; outpatient/ancillary payment detail
  1.  N FBADJRE
  1.  S FBSC=""
  1.  S DA=$P(FBIENS,",")
  1.  S DA(1)=$P(FBIENS,",",2)
  1.  S DA(2)=$P(FBIENS,",",3)
  1.  S DA(3)=$P(FBIENS,",",4)
  1.  S FBY=$G(^FBAAC(DA(3),1,DA(2),1,DA(1),1,DA,0))
  1.  S FBFPPSL=$P($G(^FBAAC(DA(3),1,DA(2),1,DA(1),1,DA,3)),U,2)
  1.  S FBADJLR=$P($$ADJLRA^FBAAFA(DA_","_DA(1)_","_DA(2)_","_DA(3)_","),U)
  1.  F FBJ=1:1 S FBADJRE=$P(FBADJLR,",",FBJ) Q:FBADJRE=""  S FBACRR(FBADJRE)=""
  1.  S FBDOS=$P($G(^FBAAC(DA(3),1,DA(2),1,DA(1),0)),U)
  1.  S FBCPT=$$GET1^DIQ(162.03,FBIENS,.01)
  1.  S FBMODLE=$$MODL^FBAAUTL4("^FBAAC("_DA(3)_",1,"_DA(2)_",1,"_DA(1)_",1,"_DA_",""M"")","E")
  1.  I $Y+$S(FBCC:FBCCI,1:10)>IOSL D PAGE^FBUCLET1,ODHD
  1.  W !!?8,$$FMTE^XLFDT(FBDOS)
  1.  W ?22,FBCPT_$S($G(FBMODLE)]"":"-"_$P(FBMODLE,","),1:"")
  1.  W ?40,$J("$"_$FN($P(FBY,U,2),",",2),11)
  1.  W ?53,$J("$"_$FN($P(FBY,U,3),",",2),12)
  1.  S:FBADJLR="" FBSC=$$GET1^DIQ(162.03,FBIENS,4)
  1.  S:FBSC]"" FBSCA(FBSC)=""
  1.  W ?70,$S(FBADJLR]"":FBADJLR,1:FBSC)
  1.  I $P($G(FBMODLE),",",2)]"" D
  1.  . N FBI
  1.  . F FBI=2:1 S FBMOD=$P(FBMODLE,",",FBI) Q:FBMOD=""  D
  1.  . . ;I $Y+4>IOSL W @IOF D HED W !,"  (continued)"
  1.  . . W !,?27,"-",FBMOD
  1.  I FBFPPSC]"" W !,?8,"FPPS Claim ID: ",FBFPPSC,?36,"FPPS Line Item: ",FBFPPSL
  1.  ; if "Other" suspend code then print description
  1.  I FBSC="4" D
  1.  . N FBGL,FBLBL
  1.  . S FBGL="^FBAAC("_DA(3)_",1,"_DA(2)_",1,"_DA(1)_",1,"
  1.  . S FBLBL="Reason for Suspension: "
  1.  . D:$Y+$S(FBCC:FBCCI,1:9)>IOSL PAGE^FBUCLET1
  1.  . D TXT^FBUCUTL2(FBGL,DA,1,"WC69I10",1,1,.FBCC,FBCCI,FBLBL)
  1.  Q
  1. PDHD ; pharmacy payment detail header
  1.  W !!?8,"RX Date",?21,"RX #"
  1.  W ?40,"Amt Claimed",?53,"Amt Approved"
  1.  W ?67,"Adj Code*"
  1.  W !?8,"------------",?21,"--------"
  1.  W ?40,"-----------",?53,"------------"
  1.  W ?67,"--------"
  1.  Q
  1. PD ; pharmacy payment detail
  1.  N FBADJRE
  1.  S FBSC=""
  1.  S DA=$P(FBIENS,",")
  1.  S DA(1)=$P(FBIENS,",",2)
  1.  S FBY=$G(^FBAA(162.1,DA(1),"RX",DA,0))
  1.  S FBFPPSL=$P($G(^FBAA(162.1,DA(1),"RX",DA,3)),U)
  1.  S FBADJLR=$P($$ADJLRA^FBRXFA(DA_","_DA(1)_","),U)
  1.  F FBJ=1:1 S FBADJRE=$P(FBADJLR,",",FBJ) Q:FBADJRE=""  S FBACRR(FBADJRE)=""
  1.  I $Y+$S(FBCC:FBCCI,1:11)>IOSL D PAGE^FBUCLET1,PDHD
  1.  W !!?8,$$FMTE^XLFDT($P(FBY,U,3)),?21,$$FMTE^XLFDT($P(FBY,U,1))
  1.  W ?40,$J("$"_$FN($P(FBY,U,4),",",2),11)
  1.  W ?53,$J("$"_$FN($P(FBY,U,16),",",2),12)
  1.  S:FBADJLR="" FBSC=$$GET1^DIQ(162.11,FBIENS,7)
  1.  S:FBSC]"" FBSCA(FBSC)=""
  1.  W ?70,$S(FBADJLR]"":FBADJLR,1:FBSC)
  1.  W !?8,"Drug Name: ",$P(FBY,U,2)
  1.  I FBFPPSC]"" W !,?8,"FPPS Claim ID: ",FBFPPSC,?36,"FPPS Line Item: ",FBFPPSL
  1.  ; if "Other" suspend code then print description
  1.  I FBSC="4" D
  1.  . N FBGL,FBLBL
  1.  . S FBGL="^FBAA(162.1,"_DA(1)_",""RX"","
  1.  . S FBLBL="Reason for Suspension: "
  1.  . D:$Y+$S(FBCC:FBCCI,1:8)>IOSL PAGE^FBUCLET1
  1.  . D TXT^FBUCUTL2(FBGL,DA,1,"WC69I10",1,1,.FBCC,FBCCI,FBLBL)
  1.  Q