Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: GMRVXPRE

GMRVXPRE.m

Go to the documentation of this file. 
  1. GMRVXPRE ;HIRMFO/RM-PREINITIALIZATION ROUTINE FOR VITALS ;7/19/96
  1.  ;;4.0;Vitals/Measurements;;Apr 25, 1997
  1. EN1 ; PRE-INITIALIZATION FOR THE VITALS PACKAGE
  1.  S GMRVER=$$VERSION^XPDUTL("GMRV") I +GMRVER=0 K GMRVER Q
  1.  I $$GET1^DID(120.5,1.4,"","LABEL")="*COMMENTS" D
  1.  .  D BMES^XPDUTL("Deleting *COMMENTS field from 120.5 file...")
  1.  .  S DA(1)=120.5,DA=1.4,DIK="^DD(120.5," D ^DIK
  1.  .  Q
  1.  S (GMRVC,GMRVDA)=0 F  S GMRVDA=$O(^GMRD(120.51,GMRVDA)) Q:GMRVDA'>0  D
  1.  .  S GMRVHELP=$P($G(^GMRD(120.51,GMRVDA,0)),"^",6) Q:GMRVHELP'>0
  1.  .  S GMRVHELP=$$GET1^DIQ(9.2,GMRVHELP_",",.01,"I") Q:GMRVHELP=""
  1.  .  K GMRVFDA S GMRVFDA(99,120.51,GMRVDA_",",5)=GMRVHELP
  1.  .  D FILE^DIE("","GMRVFDA(99)") I '$D(^TMP("DIERR",$J)),'GMRVC D
  1.  .  .  S GMRVC=1
  1.  .  .  D BMES^XPDUTL("Converting HELP FRAME data in 120.51 file...")
  1.  .  .  Q
  1.  .  K ^TMP("DIERR",$J)
  1.  .  Q
  1.  F GMRVFILE=120.52,120.53 D
  1.  .  S GMRVFNM=$$GET1^DID(GMRVFILE,"","","NAME")
  1.  .  S GMRVFINF=$P($T(@$P(GMRVFILE,".",2)),";;",2)
  1.  .  I GMRVFNM=$P(GMRVFINF,";") D
  1.  .  .  S GMRVFNM=$P(GMRVFINF,";",2)
  1.  .  .  D BMES^XPDUTL("Changing name of file #"_GMRVFILE_" to "_GMRVFNM)
  1.  .  .  K DA,DIE,DR
  1.  .  .  S DIE="^DIC(",DA=GMRVFILE,DR=".01///^S X=GMRVFNM" D ^DIE
  1.  .  .  Q
  1.  .  Q
  1.  D DELXREF(120.5,.01,"AA")
  1.  D DELXREF(120.5,.02,"AZ1")
  1.  D DELXREF(120.5,.03,"AZ2")
  1.  K GMRVFLD S GMRVDD="READ ACCESS;WRITE ACCESS;DELETE ACCESS"
  1.  D FIELD^DID(120.53,.01,"",GMRVDD,"GMRVFLD(120.53,.01)")
  1.  D FIELD^DID(120.53,1,"",GMRVDD,"GMRVFLD(120.53,1)")
  1.  D FIELD^DID(120.531,.01,"",GMRVDD,"GMRVFLD(120.531,.01)")
  1.  S GMRVFILE=0 F  S GMRVFILE=$O(GMRVFLD(GMRVFILE)) Q:GMRVFILE'>0  D
  1.  .  S GMRVFLD=0 F  S GMRVFLD=$O(GMRVFLD(GMRVFILE,GMRVFLD)) Q:GMRVFLD'>0  F GMRVDD="READ ACCESS^8","WRITE ACCESS^9","DELETE ACCESS^8.5" D
  1.  .  .  S GMRVACC=$P(GMRVDD,"^")
  1.  .  .  I $G(GMRVFLD(GMRVFILE,GMRVFLD,GMRVACC))="^" D
  1.  .  .  .  D BMES^XPDUTL("Removing "_GMRVACC_" for "_GMRVFLD_" field of "_GMRVFILE_" file/sub-file...")
  1.  .  .  .  K ^DD(GMRVFILE,GMRVFLD,$P(GMRVDD,"^",2))
  1.  .  .  .  Q
  1.  .  .  Q
  1.  .  Q
  1.  D EN^GMRVXCH0
  1.  K DA,DIE,DIK,DR,GMRVACC,GMRVC,GMRVDA,GMRVDD,GMRVER,GMRVFDA,GMRVFILE
  1.  K GMRVFINF,GMRVFLD,GMRVFNM,GMRVHELP
  1.  Q
  1. FILES ;;Old File Name;New File Name
  1. 52 ;;GMRV VITAL SITE;GMRV VITAL QUALIFIER
  1. 53 ;;GMRV VITAL QUALITY;GMRV VITAL CATEGORY
  1.  Q
  1. DELXREF(GMRVFILE,GMRVFLD,GMRVIX) ; This procedure will delete the
  1.  ; cross-refernce for specified file and field.
  1.  ;   Input variables:  GMRVFILE=file number
  1.  ;                     GMRVFLD=field number
  1.  ;                     GMRVIX=xref name
  1.  ;
  1.  N GMRV1,GMRVIXDA
  1.  S (GMRV1,GMRVIXDA)=0
  1.  F  S GMRVIXDA=$O(^DD(GMRVFILE,GMRVFLD,1,GMRVIXDA)) Q:GMRVIXDA'>0  D
  1.  .  I $P($G(^DD(GMRVFILE,GMRVFLD,1,GMRVIXDA,0)),"^",2)=GMRVIX D
  1.  .  .  I 'GMRV1 D
  1.  .  .  .  S GMRV1=1
  1.  .  .  .  D BMES^XPDUTL("Deleting """_GMRVIX_""" xref for "_GMRVFLD_" field of "_GMRVFILE_" file...")
  1.  .  .  .  Q
  1.  .  .  K ^DD(GMRVFILE,0,"IX",GMRVIX,GMRVFILE,GMRVFLD)
  1.  .  .  K ^DD(GMRVFILE,GMRVFLD,1,GMRVIXDA)
  1.  .  .  Q
  1.  .  Q
  1.  Q