Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PRCVTCA

PRCVTCA.m

Go to the documentation of this file.
  1. PRCVTCA ;WOIFO/SC-2237 CANCEL TO DYNAMED ; 5/31/05 2:31pm
  1. ;;5.1;IFCAP;**81**;Oct 20, 2000
  1. ;;Per VHA Directive 10-93-142, this routine should not be modified.
  1. Q
  1. ;PRCVTCA is called by routine PRCSEA
  1. ;This routine is extracting 2237 data when a user enters thru an
  1. ;option Cancel a Permanent Transaction [PRCSCT] and passing that
  1. ;info to routine PRCVEE1 which formats data into HL7 Message and
  1. ;then sends data to DynaMed. It also updates relevant info in Audit
  1. ;File #414.02. A bulletin is send if DM DOC ID is missing from an
  1. ;item or if record doesn't get updated properly in Audit File.
  1. ;
  1. EN(PRCVDA) ;
  1. ; Input PRCVDA = ien of top entry of the file
  1. ;Quit if system parameter is not set to DynaMed
  1. N PRCVSYS
  1. S PRCVSYS=$$GET^XPAR("SYS","PRCV COTS INVENTORY",1,"Q")
  1. Q:PRCVSYS'=1
  1. ;
  1. N PRCVRIEN,PRCVDUZ,PRCVNO,PRCVIT,PRCVEXTN,PRCVV,PRCVFLDS
  1. N PRCVSTA,CNT,PRCVTM,K,PRCVCRDT,PRCVPGDT,PRCVL,PRCVDT
  1. N PRCVI,PRCVJ,PRCVK,PRCVDID,PRCVITN,PRCVQTY,PRCVCST,PRCVDNB
  1. N PRCVDTCR,PRCVNAME,PRCVIEN,PRCVTIME,PRCVOCD,PRCV2IEN
  1. N PRCVAR,PRCVFMS,PRCVUOP,PRCVSTK,PRCVPKG,PRCVBOC,PRCVNIF
  1. N PRCVFCP,PRCVTMP,PRCVTT
  1. ;
  1. S PRCVDUZ=DUZ
  1. S PRCV2IEN=PRCVDA ; ien of the 2237 trx.
  1. S PRCVTIME=$H
  1. S PRCVEXTN=$$GET1^DIQ(410,PRCV2IEN_",",.01) ;.01 value of 2237 trx
  1. ;
  1. ;Quit if DM 2237 .01 value is not found in Audit file 414.02 'D' xref
  1. ;And check if child 2237 that was split has a parent 2237 (in
  1. ;file 410,node10,piece 2,fld51) is recorded in Audit File 414.02
  1. ;'D' x-ref.
  1. S PRCVTT=$$CHKDM^PRCVLIC(PRCVEXTN) Q:PRCVTT'=1
  1. ;
  1. D NOW^%DTC,YX^%DTC
  1. S PRCVTM=Y ;date/time in ext format MAR 07, 2005@16:08
  1. S PRCVFCP=$P($G(PRCVEXTN),"-",4)
  1. S PRCVNO="PRCVUP*"_PRCVEXTN ; .01 val in the XTMP subscript
  1. ;S PRCVNO="PRCVUP*"_PRCV2IEN ; ien in the XTMP subscript
  1. S PRCVSTA=$$GET1^DIQ(4,$$KSP^XUPARAM("INST")_",",99)
  1. S PRCVNAME=$$GET1^DIQ(200,PRCVDUZ_",",.01,"E")
  1. ;
  1. S CNT=0
  1. K ^XTMP(PRCVNO,PRCVTIME)
  1. D SETUP0 ; set up XTMP global's zero node
  1. D ITEM ; process all of the items
  1. I CNT>0 D SETUP1 ; if there is a line item then set Node 1
  1. I CNT'>0 K ^XTMP(PRCVNO,PRCVTIME)
  1. ;Call HL7 Message builder/transmitter routine
  1. ;PRCVNO is comprised of "PRCVUP*Trx#" & Trx# is Sta-fy-Qtr-FCP-seq#
  1. ;PRCVTIME is time stamp in $H format
  1. I CNT>0 D BEGIN^PRCVEE1(PRCVNO,PRCVTIME)
  1. D EXIT
  1. Q
  1. ;
  1. ITEM ;
  1. ;N PRCVAR
  1. S (PRCVI,PRCVJ,PRCVL)=0
  1. S PRCVIEN=$$GET1^DIQ(410,PRCV2IEN_",",12,"I") ;vendor ien F410N3P4
  1. S PRCVFMS=$$GET1^DIQ(440,PRCVIEN_",",34,"I") ;FMS vendor ien F440N3P4
  1. ;
  1. F S PRCVI=$O(^PRCS(410,PRCV2IEN,"IT",PRCVI)) Q:PRCVI'>0!(+PRCVI=0) D
  1. . N PRCVAR
  1. . S PRCVFLDS="2;3;4;5;6;7;17"
  1. . D GETS^DIQ(410.02,PRCVI_","_PRCV2IEN_",",PRCVFLDS,"","PRCVAR")
  1. . S PRCVDNB=$$GET1^DIQ(410.02,PRCVI_","_PRCV2IEN_",",18,"I")
  1. . D SETUP ; DO a setup in XTMP struct
  1. . Q
  1. Q
  1. ;
  1. ;
  1. SETUP ;set up XTMP ITEM node(S) & UPDATE audit file for each item on a RIL
  1. ;Order Control code^Item ien^Qty^Vendor ien^^Cost^DynaMed doc ID^Date Needed By^Unit of Purchase^Vendor Stock Number^Packaging Mult.^BOC^Nif #
  1. ;
  1. S PRCVOCD="CA" ; order control code for entire 2237 cancellation
  1. S PRCVQTY=PRCVAR(410.02,PRCVI_","_PRCV2IEN_",",2) ; qty N0P2
  1. S PRCVUOP=PRCVAR(410.02,PRCVI_","_PRCV2IEN_",",3) ; unit of purchase N0P3
  1. S PRCVBOC=PRCVAR(410.02,PRCVI_","_PRCV2IEN_",",4) ; BOC w descr N0P4
  1. S PRCVITN=PRCVAR(410.02,PRCVI_","_PRCV2IEN_",",5) ; item ien N0P5
  1. S PRCVSTK=PRCVAR(410.02,PRCVI_","_PRCV2IEN_",",6) ; stock # N0P6
  1. S PRCVCST=PRCVAR(410.02,PRCVI_","_PRCV2IEN_",",7) ; unit cost N0P7
  1. S PRCVDID=PRCVAR(410.02,PRCVI_","_PRCV2IEN_",",17) ; DM doc id N4P1
  1. I PRCVDID="" D Q ; if DM doc id is missing, send a bulletin
  1. . S XMB(1)="processing a CANCEL of the 2237 #: "_PRCVEXTN
  1. . S XMB(2)=" ...None Found"
  1. . S XMB(3)="The line item ien: "_$G(PRCVITN)_" is missing it's DM DOC ID."
  1. . K ^TMP($J,"PRCVTCA") S PRCVTMP="PRCVTCA"
  1. . S ^TMP($J,"PRCVTCA",1,0)=""
  1. . S ^TMP($J,"PRCVTCA",2,0)="2237 #: "_$G(PRCVEXTN)
  1. . S ^TMP($J,"PRCVTCA",3,0)="Item's IEN: "_$G(PRCVITN)
  1. . D DMERXMB^PRCVLIC(PRCVTMP,PRCVSTA,PRCVFCP)
  1. . Q
  1. ;S PRCVDNB=PRCVAR(410.02,PRCVI_","_PRCV2IEN_",",18) ; dt needed in external FM format N4P2
  1. ;S PRCVDT=$$HLDATE^HLFNC(PRCVDNB,"DT") ; YYYYMMDD -- hl7 format
  1. ;S PRCVDT=$$FMTE^XLFDT(PRCVDNB,"7D") ; YYYY/M/D or YYYY/MM/DD
  1. S PRCVPKG=$$GET1^DIQ(441.01,PRCVIEN_","_PRCVITN_",",1.6) ; pkg mult F441.01N0P8
  1. S PRCVNIF=$$GET1^DIQ(441,PRCVITN_",",51) ; nif no F441N0P15
  1. ;
  1. ;
  1. S CNT=CNT+1
  1. S $P(^XTMP(PRCVNO,PRCVTIME,2,CNT),"^",1)=PRCVOCD
  1. S $P(^XTMP(PRCVNO,PRCVTIME,2,CNT),"^",2)=PRCVITN
  1. S $P(^XTMP(PRCVNO,PRCVTIME,2,CNT),"^",3)=PRCVQTY
  1. S $P(^XTMP(PRCVNO,PRCVTIME,2,CNT),"^",4)=PRCVIEN
  1. S $P(^XTMP(PRCVNO,PRCVTIME,2,CNT),"^",5)=PRCVFMS
  1. S $P(^XTMP(PRCVNO,PRCVTIME,2,CNT),"^",6)=PRCVCST
  1. S $P(^XTMP(PRCVNO,PRCVTIME,2,CNT),"^",7)=PRCVDID
  1. S $P(^XTMP(PRCVNO,PRCVTIME,2,CNT),"^",8)=PRCVDNB
  1. S $P(^XTMP(PRCVNO,PRCVTIME,2,CNT),"^",9)=PRCVUOP
  1. S $P(^XTMP(PRCVNO,PRCVTIME,2,CNT),"^",10)=PRCVSTK
  1. S $P(^XTMP(PRCVNO,PRCVTIME,2,CNT),"^",11)=PRCVPKG
  1. S $P(^XTMP(PRCVNO,PRCVTIME,2,CNT),"^",12)=+PRCVBOC
  1. S $P(^XTMP(PRCVNO,PRCVTIME,2,CNT),"^",13)=PRCVNIF
  1. ;
  1. ;update Audit File 414.02 for 2237 CANCEL fields 8 and 9
  1. ;#8 date/time removed from IFCAP #9 who deleted
  1. D NOW^%DTC
  1. N PRCVZ,PRCVARR
  1. S PRCVZ=""
  1. S PRCVZ=$O(^PRCV(414.02,"B",PRCVDID,PRCVZ))
  1. I +$G(PRCVZ)'>0 D BULLET Q ;if record is missing fr 414.02 file
  1. S PRCVARR(414.02,PRCVZ_",",8)=% ; int dt/time for removing
  1. S PRCVARR(414.02,PRCVZ_",",9)=PRCVDUZ ; who deleted
  1. D UPDATE^DIE("","PRCVARR")
  1. I $D(^TMP("DIERR",$J)) D Q
  1. .S XMB(1)="processing CANCEL of a 2237 #: "_$G(PRCVEXTN)
  1. .S XMB(2)=$G(PRCVDID)
  1. .S XMB(3)="ERROR while updating AUDIT FILE #414.02"
  1. .K ^TMP($J,"PRCVTCA") S PRCVTMP="PRCVTCA"
  1. .S ^TMP($J,"PRCVTCA",1,0)=""
  1. .S ^TMP($J,"PRCVTCA",2,0)="2237 #: "_$G(PRCVEXTN)
  1. .S ^TMP($J,"PRCVTCA",3,0)="Item's IEN: "_$G(PRCVITN)
  1. .S ^TMP($J,"PRCVTCA",4,0)="DM DOC ID: "_$G(PRCVDID)
  1. .S ^TMP($J,"PRCVTCA",5,0)="Deleted By: "_$G(PRCVNAME)_" (DUZ: "_$G(PRCVDUZ)_")"
  1. .S ^TMP($J,"PRCVTCA",6,0)="Error Text: "_$G(^TMP("DIERR",$J,1,"TEXT",1))
  1. .D DMERXMB^PRCVLIC(PRCVTMP,PRCVSTA,PRCVFCP)
  1. QUIT
  1. ;
  1. SETUP0 ;set up XTMP 0 node
  1. ;Termination Date^Entry Date^Descriptive Text_Time in ext format
  1. ;D NOW^%DTC,YX^%DTC
  1. ;S PRCVTM=Y ;date/time in ext format MAR 07, 2005@16:08
  1. S PRCVCRDT=DT ; DT is FM internal dt 3050307
  1. S PRCVPGDT=$$FMADD^XLFDT(DT,5) ; purge XTMP global in 5 days
  1. ;adding extra 0 node to comply w SACC std 4/28/05
  1. S ^XTMP(PRCVNO,0)=PRCVPGDT_"^"_PRCVCRDT_"^"_"Transmit message to DynaMed for updates"
  1. S $P(^XTMP(PRCVNO,PRCVTIME,0),"^",1)=PRCVPGDT
  1. S $P(^XTMP(PRCVNO,PRCVTIME,0),"^",2)=PRCVCRDT
  1. S $P(^XTMP(PRCVNO,PRCVTIME,0),"^",3)="2237 Cancellation Update to DynaMed: "_PRCVTM
  1. Q
  1. ;
  1. SETUP1 ;set up XTMP 1 node
  1. ;Number of records^Site^DUZ^Entered By Last Name^Entered By First Name^IEN of 2237
  1. ;
  1. I $D(PRCVNAME),PRCVNAME]"" D NAMECOMP^XLFNAME(.PRCVNAME)
  1. S $P(^XTMP(PRCVNO,PRCVTIME,1),"^")=CNT ; total no of items
  1. S $P(^XTMP(PRCVNO,PRCVTIME,1),"^",2)=PRCVSTA ; Sta
  1. ;S $P(^XTMP(PRCVNO,PRCVTIME,1),"^",3)=PRCVDTCR ; dt/time created
  1. S $P(^XTMP(PRCVNO,PRCVTIME,1),"^",3)=PRCVDUZ ; DUZ
  1. S $P(^XTMP(PRCVNO,PRCVTIME,1),"^",4)=PRCVNAME("FAMILY")
  1. S $P(^XTMP(PRCVNO,PRCVTIME,1),"^",5)=PRCVNAME("GIVEN")
  1. S $P(^XTMP(PRCVNO,PRCVTIME,1),"^",6)=PRCV2IEN ; ien of 2237
  1. Q
  1. ;
  1. ;PRCVZ - record in Audit File
  1. BULLET ;Send a bulletin if record is missing from audit file
  1. I PRCVZ="" D Q
  1. .S XMB(1)="processing CANCEL of 2237 #: "_$G(PRCVEXTN)
  1. .S XMB(2)=$G(PRCVDID)
  1. .S XMB(3)="the record related to DM DOC ID is missing in AUDIT FILE #414.02"
  1. .K ^TMP($J,"PRCVTCA") S PRCVTMP="PRCVTCA"
  1. .S ^TMP($J,"PRCVTCA",1,0)=""
  1. .S ^TMP($J,"PRCVTCA",2,0)="2237 #: "_$G(PRCVEXTN)
  1. .S ^TMP($J,"PRCVTCA",3,0)="DM DOC ID: "_$G(PRCVDID)
  1. .S ^TMP($J,"PRCVTCA",4,0)="Item's IEN: "_$G(PRCVITN)
  1. .D DMERXMB^PRCVLIC(PRCVTMP,PRCVSTA,PRCVFCP)
  1. Q
  1. ;
  1. ;
  1. EXIT ;kill variables and quit
  1. K %,X,Y
  1. Q
  1. ;
  1. ;