PSDNMSP ;DOIFO/CMS - CSM RX Processed by Same Person ;18 Dec 02
;;3.0; CONTROLLED SUBSTANCES ;*41*;13 Feb 97
;Reference to ^PSDRUG( supported by IA #221
;Reference to ^PS(59 supported by IA #2621
;Reference to ^PSRX( supported by IA #1977
Q
;
ST ;CS Monitoring OPTION ENTRY
N PSDODIV,PSDCII,PSDED,PSDOUT,PSDDTN,PSDSD,X,Y,%
N DIR,DIRUT,DIROUT,DTOUT,DUOUT,POP,ZTIO,ZTSAVE,ZTSK,ZTRTN,ZTDESC,%ZIS
W !!,?5,"This report lists CS prescriptions that were entered,"
W !,?5,"finished and released by the same person.",!!
W ! D DIV^PSDNMU I '$O(PSDODIV(0))!($G(PSDOUT)) G END
S PSDDTN="Fill" D DATE^PSDNMU I '$G(PSDSD)!($G(PSDOUT)) G END
W ! D CII^PSDNMU I $G(PSDOUT)!($G(PSDCII)']"") G END
;
W ! S DIR("A")="Okay to Continue",DIR("B")="No",DIR(0)="Y" D ^DIR
I Y'=1 W " <No report>",! G END
W !!,?9,"This report should be queued to run during non-peak hours.",!
K IO("Q") S %ZIS="MQ" D ^%ZIS I POP W " <No device selected.>" G END
I $D(IO("Q")) D
.S ZTRTN="DQ^PSDNMSP",ZTDESC="CS Monitoring - PSDNMSP"
.S ZTSAVE("PSDED")="",ZTSAVE("PSDSD")="",ZTSAVE("PSDODIV(")="",ZTSAVE("PSDCII")=""
.D ^%ZTLOAD W !!?5,"TASK #",$G(ZTSK)," QUEUED!",!
I '$D(IO("Q")) U IO D DQ
K IOP,IO("Q")
END Q
;
HD ;Report heading
N PSDD,PSDL,X,Y,%
W @IOF,$$CJ^XLFSTR("CS Monitoring - RX by Same Person Report",IOM)
S PSDL="Outpatient Division(s): "
S PSDD=0
F S PSDD=$O(PSDODIV(PSDD)) Q:'PSDD S PSDL=PSDL_$P($G(PSDODIV(PSDD)),U,2) I $O(PSDODIV(PSDD)) S PSDL=PSDL_", "
W !,$$CJ^XLFSTR(PSDL,IOM)
W !,$$CJ^XLFSTR("Fill Date range: "_$P(PSDSD,U,2)_" thru "_$P(PSDED,U,2),IOM)
S PSDL="Controlled Substance schedule(s): "
F PSDD=1:1:4 I $P(PSDCII,",",PSDD) S PSDL=PSDL_$P(PSDCII,",",PSDD) I $P(PSDCII,",",(PSDD+1)) S PSDL=PSDL_", "
I +PSDCII W !,$$CJ^XLFSTR(PSDL,IOM)
W !,"Station: ",$E($G(PSDIV),1,13),?25,"Report Run Date: "
S PSDPG=PSDPG+1
D NOW^%DTC W $$FMTE^XLFDT(%),?70,"PAGE: ",PSDPG
W !,$$REPEAT^XLFSTR("=",IOM)
QUIT
;
DQ ;Report Run
N PSDA,PSDFD,PSDIDT,PSDIV,PSDOUT,PSDP,PSDPG,PSDRG,PSDUZ,PSDX,PSDX0,PSDX2,PSDXOR1,PSDY,X,Y,%
K ^TMP("PSDNMSP",$J)
I IOST?1"C-".E W !!,?10,"Compiling report, please wait ..."
S PSDFD=+PSDSD
F S PSDFD=$O(^PSRX("AD",PSDFD)) Q:('PSDFD)!(PSDFD]+PSDED) D
. S PSDX=0
. F S PSDX=$O(^PSRX("AD",PSDFD,PSDX)) Q:'PSDX D
. . S PSDX0=$G(^PSRX(PSDX,0)) I PSDX0']"" Q
. . S PSDX2=$G(^PSRX(PSDX,2))
. . I '$D(PSDODIV(+$P(PSDX2,U,9))) Q
. . S PSDRG=$G(^PSDRUG(+$P(PSDX0,U,6),0))
. . S PSDP=0
. . F PSDY=1:1:4 S PSDA=+$P(PSDCII,",",PSDY) I PSDA,$P(PSDRG,U,3)[PSDA S PSDP=1 Q
. . I 'PSDP Q
. . S PSDUZ=+$P(PSDX0,U,16) I 'PSDUZ Q
. . I PSDUZ'=+$P(PSDX2,U,3) Q
. . S PSDXOR1=$G(^PSRX(PSDX,"OR1"))
. . I PSDUZ'=+$P(PSDXOR1,U,5) Q
. . S Y=PSDFD D D^DIQ S PSDIDT=Y
. . S ^TMP("PSDNMSP",$J,$S(+$P(PSDX2,U,9):$P($G(^PS(59,+$P(PSDX2,U,9),0)),U,1),1:"UNKNOWN"),$P($G(^VA(200,+PSDUZ,0)),U,1),PSDX)=$P(PSDX0,U,1)_U_PSDIDT_U_$P(PSDRG,U,1)
;
PRT ;Report print
S PSDPG=0,PSDOUT=0
I '$D(^TMP("PSDNMSP",$J)) D G DQQ
. S PSDIV="" S PSDPG=0 D HD,PHD
. W !!,?10,"<<<< NO DATA FOUND >>>>",!
S PSDIV=""
F S PSDIV=$O(^TMP("PSDNMSP",$J,PSDIV)) Q:(PSDIV="")!(PSDOUT) D
. S PSDPG=0 D HD,PHD
. S PSDUZ=""
. F S PSDUZ=$O(^TMP("PSDNMSP",$J,PSDIV,PSDUZ)) Q:(PSDUZ="")!(PSDOUT) D
. . I ($Y+3)>IOSL D PAGE Q:PSDOUT D HD,PHD
. . W !!,PSDUZ
. . S PSDX=0
. . F S PSDX=$O(^TMP("PSDNMSP",$J,PSDIV,PSDUZ,PSDX)) Q:('PSDX)!(PSDOUT) D
. . . S PSDY=$G(^TMP("PSDNMSP",$J,PSDIV,PSDUZ,PSDX))
. . . I ($Y+3)>IOSL D PAGE Q:PSDOUT D HD,PHD
. . . W !,$P(PSDY,U,1),?25,$P(PSDY,U,2),?40,$P(PSDY,U,3)
. I '$G(PSDOUT),$O(^TMP("PSDNMSP",$J,PSDIV))]"" D PAGE
;
DQQ W ! K PSDCII,PSDED,PSDODIV,PSDSD,^TMP("PSDNMSP",$J) D ^%ZISC Q
;
PHD W !,"Pharmacy User"
W !,"RX#",?25,"Fill Date",?40,"Drug Name"
W !,$$REPEAT^XLFSTR("_",IOM)
Q
PAGE ;
N DIR,DIRUT,DTOUT,DUOUT,X,Y
I IOST?1"C-".E S DIR(0)="E" D ^DIR W !
I ($D(DTOUT))!($D(DIRUT)) S PSDOUT=1 Q:$G(PSDOUT)=1
Q
;
EOR ;PSDNMSP - CSM RX Processed by Same Person; 18 DEC 02
--- Routine Detail --- with STRUCTURED ROUTINE LISTING ---[H[J[2J[HPSDNMSP 4065 printed Dec 13, 2024@01:46:55 Page 2
PSDNMSP ;DOIFO/CMS - CSM RX Processed by Same Person ;18 Dec 02
+1 ;;3.0; CONTROLLED SUBSTANCES ;*41*;13 Feb 97
+2 ;Reference to ^PSDRUG( supported by IA #221
+3 ;Reference to ^PS(59 supported by IA #2621
+4 ;Reference to ^PSRX( supported by IA #1977
+5 QUIT
+6 ;
ST ;CS Monitoring OPTION ENTRY
+1 NEW PSDODIV,PSDCII,PSDED,PSDOUT,PSDDTN,PSDSD,X,Y,%
+2 NEW DIR,DIRUT,DIROUT,DTOUT,DUOUT,POP,ZTIO,ZTSAVE,ZTSK,ZTRTN,ZTDESC,%ZIS
+3 WRITE !!,?5,"This report lists CS prescriptions that were entered,"
+4 WRITE !,?5,"finished and released by the same person.",!!
+5 WRITE !
DO DIV^PSDNMU
IF '$ORDER(PSDODIV(0))!($GET(PSDOUT))
GOTO END
+6 SET PSDDTN="Fill"
DO DATE^PSDNMU
IF '$GET(PSDSD)!($GET(PSDOUT))
GOTO END
+7 WRITE !
DO CII^PSDNMU
IF $GET(PSDOUT)!($GET(PSDCII)']"")
GOTO END
+8 ;
+9 WRITE !
SET DIR("A")="Okay to Continue"
SET DIR("B")="No"
SET DIR(0)="Y"
DO ^DIR
+10 IF Y'=1
WRITE " <No report>",!
GOTO END
+11 WRITE !!,?9,"This report should be queued to run during non-peak hours.",!
+12 KILL IO("Q")
SET %ZIS="MQ"
DO ^%ZIS
IF POP
WRITE " <No device selected.>"
GOTO END
+13 IF $DATA(IO("Q"))
Begin DoDot:1
+14 SET ZTRTN="DQ^PSDNMSP"
SET ZTDESC="CS Monitoring - PSDNMSP"
+15 SET ZTSAVE("PSDED")=""
SET ZTSAVE("PSDSD")=""
SET ZTSAVE("PSDODIV(")=""
SET ZTSAVE("PSDCII")=""
+16 DO ^%ZTLOAD
WRITE !!?5,"TASK #",$GET(ZTSK)," QUEUED!",!
End DoDot:1
+17 IF '$DATA(IO("Q"))
USE IO
DO DQ
+18 KILL IOP,IO("Q")
END QUIT
+1 ;
HD ;Report heading
+1 NEW PSDD,PSDL,X,Y,%
+2 WRITE @IOF,$$CJ^XLFSTR("CS Monitoring - RX by Same Person Report",IOM)
+3 SET PSDL="Outpatient Division(s): "
+4 SET PSDD=0
+5 FOR
SET PSDD=$ORDER(PSDODIV(PSDD))
if 'PSDD
QUIT
SET PSDL=PSDL_$PIECE($GET(PSDODIV(PSDD)),U,2)
IF $ORDER(PSDODIV(PSDD))
SET PSDL=PSDL_", "
+6 WRITE !,$$CJ^XLFSTR(PSDL,IOM)
+7 WRITE !,$$CJ^XLFSTR("Fill Date range: "_$PIECE(PSDSD,U,2)_" thru "_$PIECE(PSDED,U,2),IOM)
+8 SET PSDL="Controlled Substance schedule(s): "
+9 FOR PSDD=1:1:4
IF $PIECE(PSDCII,",",PSDD)
SET PSDL=PSDL_$PIECE(PSDCII,",",PSDD)
IF $PIECE(PSDCII,",",(PSDD+1))
SET PSDL=PSDL_", "
+10 IF +PSDCII
WRITE !,$$CJ^XLFSTR(PSDL,IOM)
+11 WRITE !,"Station: ",$EXTRACT($GET(PSDIV),1,13),?25,"Report Run Date: "
+12 SET PSDPG=PSDPG+1
+13 DO NOW^%DTC
WRITE $$FMTE^XLFDT(%),?70,"PAGE: ",PSDPG
+14 WRITE !,$$REPEAT^XLFSTR("=",IOM)
+15 QUIT
+16 ;
DQ ;Report Run
+1 NEW PSDA,PSDFD,PSDIDT,PSDIV,PSDOUT,PSDP,PSDPG,PSDRG,PSDUZ,PSDX,PSDX0,PSDX2,PSDXOR1,PSDY,X,Y,%
+2 KILL ^TMP("PSDNMSP",$JOB)
+3 IF IOST?1"C-".E
WRITE !!,?10,"Compiling report, please wait ..."
+4 SET PSDFD=+PSDSD
+5 FOR
SET PSDFD=$ORDER(^PSRX("AD",PSDFD))
if ('PSDFD)!(PSDFD]+PSDED)
QUIT
Begin DoDot:1
+6 SET PSDX=0
+7 FOR
SET PSDX=$ORDER(^PSRX("AD",PSDFD,PSDX))
if 'PSDX
QUIT
Begin DoDot:2
+8 SET PSDX0=$GET(^PSRX(PSDX,0))
IF PSDX0']""
QUIT
+9 SET PSDX2=$GET(^PSRX(PSDX,2))
+10 IF '$DATA(PSDODIV(+$PIECE(PSDX2,U,9)))
QUIT
+11 SET PSDRG=$GET(^PSDRUG(+$PIECE(PSDX0,U,6),0))
+12 SET PSDP=0
+13 FOR PSDY=1:1:4
SET PSDA=+$PIECE(PSDCII,",",PSDY)
IF PSDA
IF $PIECE(PSDRG,U,3)[PSDA
SET PSDP=1
QUIT
+14 IF 'PSDP
QUIT
+15 SET PSDUZ=+$PIECE(PSDX0,U,16)
IF 'PSDUZ
QUIT
+16 IF PSDUZ'=+$PIECE(PSDX2,U,3)
QUIT
+17 SET PSDXOR1=$GET(^PSRX(PSDX,"OR1"))
+18 IF PSDUZ'=+$PIECE(PSDXOR1,U,5)
QUIT
+19 SET Y=PSDFD
DO D^DIQ
SET PSDIDT=Y
+20 SET ^TMP("PSDNMSP",$JOB,$SELECT(+$PIECE(PSDX2,U,9):$PIECE($GET(^PS(59,+$PIECE(PSDX2,U,9),0)),U,1),1:"UNKNOWN"),$PIECE($GET(^VA(200,+PSDUZ,0)),U,1),PSDX)=$PIECE(PSDX0,U,1)_U_PSDIDT_U_$PIECE(PSDRG,U,1)
End DoDot:2
End DoDot:1
+21 ;
PRT ;Report print
+1 SET PSDPG=0
SET PSDOUT=0
+2 IF '$DATA(^TMP("PSDNMSP",$JOB))
Begin DoDot:1
+3 SET PSDIV=""
SET PSDPG=0
DO HD
DO PHD
+4 WRITE !!,?10,"<<<< NO DATA FOUND >>>>",!
End DoDot:1
GOTO DQQ
+5 SET PSDIV=""
+6 FOR
SET PSDIV=$ORDER(^TMP("PSDNMSP",$JOB,PSDIV))
if (PSDIV="")!(PSDOUT)
QUIT
Begin DoDot:1
+7 SET PSDPG=0
DO HD
DO PHD
+8 SET PSDUZ=""
+9 FOR
SET PSDUZ=$ORDER(^TMP("PSDNMSP",$JOB,PSDIV,PSDUZ))
if (PSDUZ="")!(PSDOUT)
QUIT
Begin DoDot:2
+10 IF ($Y+3)>IOSL
DO PAGE
if PSDOUT
QUIT
DO HD
DO PHD
+11 WRITE !!,PSDUZ
+12 SET PSDX=0
+13 FOR
SET PSDX=$ORDER(^TMP("PSDNMSP",$JOB,PSDIV,PSDUZ,PSDX))
if ('PSDX)!(PSDOUT)
QUIT
Begin DoDot:3
+14 SET PSDY=$GET(^TMP("PSDNMSP",$JOB,PSDIV,PSDUZ,PSDX))
+15 IF ($Y+3)>IOSL
DO PAGE
if PSDOUT
QUIT
DO HD
DO PHD
+16 WRITE !,$PIECE(PSDY,U,1),?25,$PIECE(PSDY,U,2),?40,$PIECE(PSDY,U,3)
End DoDot:3
End DoDot:2
+17 IF '$GET(PSDOUT)
IF $ORDER(^TMP("PSDNMSP",$JOB,PSDIV))]""
DO PAGE
End DoDot:1
+18 ;
DQQ WRITE !
KILL PSDCII,PSDED,PSDODIV,PSDSD,^TMP("PSDNMSP",$JOB)
DO ^%ZISC
QUIT
+1 ;
PHD WRITE !,"Pharmacy User"
+1 WRITE !,"RX#",?25,"Fill Date",?40,"Drug Name"
+2 WRITE !,$$REPEAT^XLFSTR("_",IOM)
+3 QUIT
PAGE ;
+1 NEW DIR,DIRUT,DTOUT,DUOUT,X,Y
+2 IF IOST?1"C-".E
SET DIR(0)="E"
DO ^DIR
WRITE !
+3 IF ($DATA(DTOUT))!($DATA(DIRUT))
SET PSDOUT=1
if $GET(PSDOUT)=1
QUIT
+4 QUIT
+5 ;
EOR ;PSDNMSP - CSM RX Processed by Same Person; 18 DEC 02
