Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SCAPMC11

SCAPMC11.m

Go to the documentation of this file. 
  1. SCAPMC11 ;ALB/REW - Team API's: PTTP ; JUN 30, 1995
  1.  ;;5.3;Scheduling;**41**;AUG 13, 1993
  1.  ;;1.0
  1. PTTP(SCTP,SCDATES,SCLIST,SCERR) ; -- list of patient team position assignments
  1.  ; input:
  1.  ;  SCTP = ien of TEAM POSITION [required]
  1.  ;  SCDATES("BEGIN") = begin date to search (inclusive)
  1.  ;                      [default: TODAY]
  1.  ;        ("END")   = end date to search (inclusive)
  1.  ;                      [default: TODAY]
  1.  ;        ("INCL")  = 1: only use patients who were assigned to
  1.  ;                       position for entire date range
  1.  ;                    0: anytime in date range
  1.  ;                      [default: 1] 
  1.  ;  SCLIST -array name to store list
  1.  ;          [ex. ^TMP("SCPT",$J)]
  1.  ;        
  1.  ;  SCERR = array NAME to store error messages.
  1.  ;          [ex. ^TMP("ORXX",$J)]
  1.  ;
  1.  ; Output:
  1.  ;  SCLIST() = array of patients
  1.  ;             Format:
  1.  ;               Subscript: Sequential # from 1 to n
  1.  ;               Piece     Description
  1.  ;                 1       IEN of PATIENT file entry
  1.  ;                 2       Name of patient
  1.  ;                 3       IEN of Patient Team Position Assignment
  1.  ;                 4       Activation Date
  1.  ;                 5       Inactivation Date
  1.  ;                 6       Patient's Long ID - (SSN)
  1.  ;
  1.  ;  SCERR() = Array of DIALOG file messages(errors) .
  1.  ;  @SCERR@(0)=number of errors, undefined if none
  1.  ;             Foramt:
  1.  ;               Subscript: Sequential # from 1 to n
  1.  ;               Piece     Description
  1.  ;                 1       IEN of DIALOG file
  1.  ;
  1.  ;   Returned: 1 if ok, 0 if error
  1.  ;
  1.  ;
  1. ST N SCTPA,SCPTA,SCPTA0,SCPTMA,SCPTPA,SCPTPA0
  1.  N SCLSEQ,SCN,SCESEQ,SCPARM,SCP,SCBEGIN,SCEND,SCINCL,SCDTS
  1.  G:'$$OKDATA PRACQ ;check/setup variables
  1.  ; -- loop through patient team position assignments
  1. LP S SCPTMA=0
  1.  F  S SCPTMA=$O(^SCPT(404.43,"APTPA",SCTP,SCPTMA)) Q:'SCPTMA  D
  1.  .S SCPTPA=0
  1.  .F  S SCPTPA=$O(^SCPT(404.43,"APTPA",SCTP,SCPTMA,SCPTPA)) Q:'SCPTPA  D
  1.  ..S SCPTPA0=$G(^SCPT(404.43,SCPTPA,0))
  1.  ..Q:'SCPTPA0
  1.  ..Q:'$$DTCHK^SCAPU1(SCBEGIN,SCEND,SCINCL,$P(SCPTPA0,U,3),$P(SCPTPA0,U,4))
  1.  ..D BLD(.SCLIST,SCPTPA,SCPTPA0)
  1. PRACQ Q $G(@SCERR@(0))<1
  1.  ;
  1.  ;
  1. BLD(SCLIST,SCPTTPA,SCPTTPA0) ; build list
  1.  ; SCPTTPA    - ien of patient team position assignment file #404.43
  1.  ; SCEFFDT - negative of effective date
  1.  ; SCN     - current subscript (counter) 1->n
  1.  ; SCPTTPA0 - IS 0 node of Pt Team Pos Assnt(404.43) 1st piece:pt tm ass
  1.  ; 
  1.  ; this builds the array:
  1.  ;   sclist(1->n)=sc2^ptname^effdt^inactdt
  1.  ;    for each scpta zero node passed to it
  1.  Q:'SCPTTPA!('SCPTTPA0)  ;add error trapping?
  1.  Q:$D(@SCLIST@("SCPTTPA",+SCPTTPA0,SCPTTPA))
  1.  N SCEFFDT,SCCNT,DFN
  1.  S DFN=+$G(^SCPT(404.42,+SCPTTPA0,0))
  1.  Q:$D(^TMP("SCMC",$J,"EXCLUDE PT","SCPTA",+DFN))
  1.  S SCN=$G(@SCLIST@(0),0)+1
  1.  S @SCLIST@(0)=SCN
  1.  S @SCLIST@(SCN)=DFN_U_$P($G(^DPT(DFN,0)),U,1)_U_SCPTTPA_U_$P(SCPTTPA0,U,3)_U_$P(SCPTTPA0,U,4)_U_$P($G(^DPT(DFN,.36)),U,3)
  1.  S @SCLIST@("SCPTTPA",+SCPTTPA0,SCPTTPA,SCN)=""
  1.  S @SCLIST@("SCPTA",DFN,SCN)=""
  1.  Q
  1. OKDATA() ;check/setup variables
  1.  N SCOK
  1.  S SCOK=1
  1.  D INIT^SCAPMCU1(.SCOK) ; set default dates & error array (if undefined)
  1.  IF '$D(^SCTM(404.57,+$G(SCTP),0)) D  S SCOK=0
  1.  . S SCPARM("POSITION")=$G(SCTP,"Undefined")
  1.  . D ERR^SCAPMCU1(.SCESEQ,4045701,.SCPARM,"",.SCERR)
  1.  ; -- is it a valid TEAM ien passed (Error # 4045701 in DIALOG file)
  1.  IF '$D(^SCTM(404.57,+SCTP,0)) D  S SCOK=0
  1.  . S SCPARM("TEAM")=SCTP
  1.  . D ERR^SCAPMCU1(SCESEQ,4045701,.SCPARM,"",.SCERR)
  1.  Q SCOK