SDES2RECLLREQ2 ; ALB/MCB - VISTA SCHEDULING CREATE/EDIT RECALL REQUESTS 2 ; MAY 05, 2026
;;5.3;Scheduling;**944**;Aug 13, 1993;Build 2
;;Per VHA Directive 6402, this routine should not be modified
;
; Reference to DUZ^XUP is supported by IA #7487
;
Q ;No Direct Call
;
;
CREATERECREQ(RETN,SDCONTEXT,SDINPUT) ;SDES2 CREATE RECALL REQUEST 2
N CAFDA,ERRORS,SDRECREQ,SDFDA,SDMSG,SDIEN,CAERR,REQUEST
; Newed the following to address variables leaking from external APIs/Functions
N %,DG,DIC,DICR,DIW
D VALCONTEXT^SDES2VALCONTEXT(.ERRORS,.SDCONTEXT)
I $D(ERRORS) S ERRORS("Request","IEN")="" D BUILDJSON^SDES2JSON(.RETN,.ERRORS) Q
I $G(SDCONTEXT("USER DUZ"))'="" N DUZ D DUZ^XUP(SDCONTEXT("USER DUZ"))
S SDINPUT("RECALL IEN")="+1"
S SDINPUT("DATE ENTERED")=$$VALIDATERCDTNTRD(.ERRORS,$G(SDINPUT("DATE ENTERED")),SDINPUT("RECALL IEN"))
D VALIDATE(.ERRORS,.SDINPUT)
I $O(ERRORS("Error",""))'="" D RETURNERROR(.ERRORS,.SDRECREQ,.RETN,SDINPUT("RECALL IEN")) Q
D BLDREC(.SDFDA,.SDINPUT,.SDCONTEXT)
D UPDATE^DIE("","SDFDA","SDIEN","SDMSG") K SDFDA
I $D(SDMSG) D ERRLOG^SDES2JSON(.ERRORS,134),RETURNERROR(.ERRORS,.SDRECREQ,.RETN,SDINPUT("RECALL IEN")) Q
D BLDCOMAUD(.CAFDA,.SDINPUT,SDIEN(1),"")
D:$D(CAFDA) UPDATE^DIE("","CAFDA","","CAERR") K CAFDA
S SDRECREQ("Request","IEN")=SDIEN(1)
;
D GETRECALL^SDES2GETRECALL(.REQUEST,SDIEN(1),SDINPUT("DFN"))
I $D(ERRORS) M ERRORS("Request","IEN")=REQUEST("Request","IEN") D BUILDJSON^SDES2JSON(.RETN,.ERRORS) Q
D BUILDJSON^SDES2JSON(.RETN,.REQUEST)
Q
;
;SDES2 EDIT RECALL REQUEST 2
UPDRECALLREQ(RETN,SDCONTEXT,SDINPUT) ;RECALLIEN,DFN,ACCNO,SDCMT,FASTING,APPTP,RRPROVIEN,CLINIEN,APPTLEN,DATE,RECPPDT,DAPTDT,USERIEN,SECPDT,EAS) ;update recall request
N CAFDA,ERRORS,LASTNOTE,SDRECREQ,SDFDA,SDMSG,SDIEN,CAERR,REQUEST
; Newed the following to address variables leaking from external APIs/Functions
N DG,DIC,DICR,DIW
D VALCONTEXT^SDES2VALCONTEXT(.ERRORS,.SDCONTEXT)
I $D(ERRORS) S ERRORS("Request","IEN")="" D BUILDJSON^SDES2JSON(.RETN,.ERRORS) Q
I $G(SDCONTEXT("USER DUZ"))'="" N DUZ D DUZ^XUP(SDCONTEXT("USER DUZ"))
D VALIDATE(.ERRORS,.SDINPUT)
I $O(ERRORS("Error",""))'="" D RETURNERROR(.ERRORS,.SDRECREQ,.RETN,SDINPUT("RECALL IEN")) Q
S LASTNOTE=$$GET1^DIQ(403.5,SDINPUT("RECALL IEN")_",",2.5,"E")
D BLDREC(.SDFDA,.SDINPUT,.SDCONTEXT)
D FILE^DIE(,"SDFDA","SDMSG") K SDFDA
I $D(SDMSG) D ERRLOG^SDES2JSON(.ERRORS,134),RETURNERROR(.ERRORS,.SDRECREQ,.RETN,SDINPUT("RECALL IEN")) Q
D BLDCOMAUD(.CAFDA,.SDINPUT,SDINPUT("RECALL IEN"),LASTNOTE)
D:$D(CAFDA) UPDATE^DIE("","CAFDA","","CAERR") K CAFDA
S SDRECREQ("Request","IEN")=SDINPUT("RECALL IEN")
;
D GETRECALL^SDES2GETRECALL(.REQUEST,SDINPUT("RECALL IEN"),SDINPUT("DFN"))
I $D(ERRORS) M ERRORS("Request","IEN")=REQUEST("Request","IEN") D BUILDJSON^SDES2JSON(.RETN,.ERRORS) Q
D BUILDJSON^SDES2JSON(.RETN,.REQUEST)
Q
;
BLDREC(SDFDA,SDINPUT,SDCONTEXT) ;build and file record
N RECALLIEN
S RECALLIEN=SDINPUT("RECALL IEN")
S SDFDA=$NA(SDFDA(403.5,RECALLIEN_",")) ;recall
S SDFDA(403.5,RECALLIEN_",",.01)=SDINPUT("DFN")
S:$G(SDINPUT("ACCESSION NUMBER"))'="" SDFDA(403.5,RECALLIEN_",",2)=$E(SDINPUT("ACCESSION NUMBER"),1,25)
S:$G(SDINPUT("COMMENT"))'="" SDFDA(403.5,RECALLIEN_",",2.5)=$E(SDINPUT("COMMENT"),1,80)
S SDFDA(403.5,RECALLIEN_",",2.6)=SDINPUT("FASTING")
S SDFDA(403.5,RECALLIEN_",",3)=SDINPUT("APPOINTMENT TYPE")
S SDFDA(403.5,RECALLIEN_",",4)=SDINPUT("RECALL PROVIDER IEN")
S SDFDA(403.5,RECALLIEN_",",4.5)=SDINPUT("CLINIC IEN")
S:SDINPUT("APPOINTMENT LENGTH")'="" SDFDA(403.5,RECALLIEN_",",4.7)=SDINPUT("APPOINTMENT LENGTH")
S SDFDA(403.5,RECALLIEN_",",5)=SDINPUT("RECALL DATE")
S:$G(SDINPUT("RECALL DATE PER PATIENT"))'="" SDFDA(403.5,RECALLIEN_",",5.5)=SDINPUT("RECALL DATE PER PATIENT")
S:$G(SDINPUT("DATE REMINDER SENT"))'="" SDFDA(403.5,RECALLIEN_",",6)=SDINPUT("DATE REMINDER SENT")
S SDFDA(403.5,RECALLIEN_",",7)=DUZ
S:RECALLIEN="+1" SDFDA(403.5,RECALLIEN_",",7.5)=SDINPUT("DATE ENTERED") ;only add if creating new record, cannot edit
S:$G(SDINPUT("SECOND PRINT DATE"))'="" SDFDA(403.5,RECALLIEN_",",8)=SDINPUT("SECOND PRINT DATE")
S SDFDA(403.5,RECALLIEN_",",100)=$G(SDCONTEXT("ACHERON AUDIT ID"))
Q
;
BLDCOMAUD(CAFDA,SDINPUT,RECALLIEN,LASTNOTE) ;
; 403.57 COMMENT AUDIT multiple
Q:'$L(SDINPUT("COMMENT"))
N LASTLENGTH,NEWLENGTH,NEWNOTE
S LASTLENGTH=$L(LASTNOTE),NEWLENGTH=$L(SDINPUT("COMMENT"))
S NEWNOTE=$E($E(SDINPUT("COMMENT"),1,80),(LASTLENGTH+1),NEWLENGTH)
Q:'$L(NEWNOTE)
S CAFDA(403.57,"+1,"_RECALLIEN_",",.01)=$$NOW^XLFDT
S CAFDA(403.57,"+1,"_RECALLIEN_",",1)=DUZ
S CAFDA(403.57,"+1,"_RECALLIEN_",",2)=NEWNOTE
Q
;
VALIDATE(ERRORS,SDINPUT) ;
N OLDDFN
S OLDDFN=""
S SDINPUT("RECALL IEN")=$$VALIDATERECALIEN(.ERRORS,$G(SDINPUT("RECALL IEN")))
I '$D(ERRORS),SDINPUT("RECALL IEN")'="+1" S OLDDFN=$$GET1^DIQ(403.5,SDINPUT("RECALL IEN"),.01,"I")
S SDINPUT("DFN")=$$VALIDATEDFN(.ERRORS,$G(SDINPUT("DFN")),OLDDFN)
S SDINPUT("FASTING")=$$VALIDATEFASTING(.ERRORS,$G(SDINPUT("FASTING")))
S SDINPUT("APPOINTMENT TYPE")=$$VALIDATEAPPTP(.ERRORS,$G(SDINPUT("APPOINTMENT TYPE")))
S SDINPUT("RECALL PROVIDER IEN")=$$VALIDATERRPRVIEN(.ERRORS,$G(SDINPUT("RECALL PROVIDER IEN")))
S SDINPUT("CLINIC IEN")=$$VALIDATECLINIEN(.ERRORS,$G(SDINPUT("CLINIC IEN")))
S SDINPUT("RECALL DATE")=$$VALIDATERECALLDT(.ERRORS,$G(SDINPUT("RECALL DATE")))
S SDINPUT("APPOINTMENT LENGTH")=$$VALIDATEAPPTLEN(.ERRORS,$G(SDINPUT("APPOINTMENT LENGTH")))
S SDINPUT("RECALL DATE PER PATIENT")=$$VALIDATERECPPDT(.ERRORS,$G(SDINPUT("RECALL DATE PER PATIENT")))
S SDINPUT("DATE REMINDER SENT")=$$VALIDATEDAPTDT(.ERRORS,$G(SDINPUT("DATE REMINDER SENT")))
S SDINPUT("SECOND PRINT DATE")=$$VALIDATESECPDT(.ERRORS,$G(SDINPUT("SECOND PRINT DATE")))
S SDINPUT("COMMENT")=$$VALIDATESDCMT(.ERRORS,$G(SDINPUT("COMMENT")))
S SDINPUT("ACCESSION NUMBER")=$$VALIDATEACCNUM(.ERRORS,$G(SDINPUT("ACCESSION NUMBER")))
Q
;
VALIDATERECALIEN(ERRORS,RECALLIEN) ;Validate Recall IEN
I $G(RECALLIEN)="" D ERRLOG^SDES2JSON(.ERRORS,16) Q RECALLIEN
I (RECALLIEN'="+1")&('$D(^SD(403.5,$G(RECALLIEN)))) D ERRLOG^SDES2JSON(.ERRORS,17) Q RECALLIEN
;check that user has the correct security key
I $$KEY(RECALLIEN)>0 D ERRLOG^SDES2JSON(.ERRORS,135)
Q RECALLIEN
;
VALIDATEDFN(ERRORS,DFN,OLDDFN) ;Validate Patient DFN
D VALPATDFN^SDES2VAL2(.ERRORS,$G(DFN),1)
I DFN'="",OLDDFN'="",DFN'=OLDDFN D ERRLOG^SDES2JSON(.ERRORS,2,"Patient ID on Recall doesn't match passed in Patient ID")
Q DFN
;
VALIDATEFASTING(ERRORS,FASTING) ;Validate Fasting
I FASTING="" D ERRLOG^SDES2JSON(.ERRORS,141) Q FASTING
S FASTING=$S($$UP^XLFSTR(FASTING)="FASTING":"f",$$UP^XLFSTR(FASTING)="NON-FASTING":"n",$$UP^XLFSTR(FASTING)="F":"f",$$UP^XLFSTR(FASTING)="N":"n",FASTING="@":"@",1:138)
I FASTING=138 D ERRLOG^SDES2JSON(.ERRORS,138)
Q FASTING
;
VALIDATEAPPTP(ERRORS,APPTP) ;Validate Appointment Type from RECALL REMINDERS APPT TYPE (#403.51)
I APPTP="" D ERRLOG^SDES2JSON(.ERRORS,139) Q APPTP
S APPTP=$O(^SD(403.51,"B",APPTP,""))
I +APPTP,$D(^SD(403.51,APPTP,0)) Q APPTP
I +APPTP,'$D(^SD(403.51,APPTP,0)) D ERRLOG^SDES2JSON(.ERRORS,132) Q APPTP
I APPTP="" D ERRLOG^SDES2JSON(.ERRORS,139) Q APPTP
Q APPTP
;
VALIDATERRPRVIEN(ERRORS,RRPROVIEN) ;Validate Recall Provider IEN
I RRPROVIEN="" D ERRLOG^SDES2JSON(.ERRORS,137) Q RRPROVIEN
I $G(RRPROVIEN)'="",'$D(^SD(403.54,RRPROVIEN)) D ERRLOG^SDES2JSON(.ERRORS,131)
Q RRPROVIEN
;
VALIDATECLINIEN(ERRORS,CLINIEN) ;Validate Clinic IEN
I CLINIEN="" D ERRLOG^SDES2JSON(.ERRORS,18) Q CLINIEN
I CLINIEN'="",'$D(^SC(CLINIEN)) D ERRLOG^SDES2JSON(.ERRORS,19)
Q CLINIEN
;
VALIDATERECALLDT(ERRORS,RECALLDATE) ;Validate Recall Date
I RECALLDATE="" D ERRLOG^SDES2JSON(.ERRORS,140) Q RECALLDATE
I RECALLDATE'="" S RECALLDATE=$$ISOTFM^SDAMUTDT(RECALLDATE)
I RECALLDATE=-1 D ERRLOG^SDES2JSON(.ERRORS,133)
Q RECALLDATE
;
VALIDATERCDTNTRD(ERRORS,RECDTENTRD,RECALLIEN) ;Validate Recall Date Entered
I RECALLIEN'="+1" Q "" ; This is an IEN, so can't edit Recall Date Entered
I ($G(RECDTENTRD)'="") S RECDTENTRD=$$ISOTFM^SDAMUTDT(RECDTENTRD)
I (RECDTENTRD=-1)!(RECDTENTRD="") S RECDTENTRD=DT ;
Q RECDTENTRD
;
VALIDATEAPPTLEN(ERRORS,LENGTHOFAPPT) ;Validate Length of Appointment
S LENGTHOFAPPT=$G(LENGTHOFAPPT,"") I LENGTHOFAPPT="" Q LENGTHOFAPPT
I '+LENGTHOFAPPT D ERRLOG^SDES2JSON(.ERRORS,116) Q LENGTHOFAPPT
I LENGTHOFAPPT'="" S:((+LENGTHOFAPPT<10)!(+LENGTHOFAPPT>240)) LENGTHOFAPPT=""
Q LENGTHOFAPPT
;
VALIDATERECPPDT(ERRORS,RECPPTDT) ;Validate Recall Date Per Patient
S RECPPTDT=$G(RECPPTDT,"") S RECPPTDT=$$ISOTFM^SDAMUTDT(RECPPTDT)
I RECPPTDT=-1 S RECPPTDT="" ;VSE-2396
Q RECPPTDT
;
VALIDATEDAPTDT(ERRORS,DTRMSENT) ;Validate Date Reminder Sent
S DTRMSENT=$G(DTRMSENT,"")
S DTRMSENT=$$ISOTFM^SDAMUTDT(DTRMSENT)
I DTRMSENT=-1 S DTRMSENT="" ;VSE-2396
Q DTRMSENT
;
VALIDATESECPDT(ERRORS,SECPRNTDT) ;Validate Second Print Date
S SECPRNTDT=$G(SECPRNTDT,"")
I SECPRNTDT'="" S SECPRNTDT=$$ISOTFM^SDAMUTDT(SECPRNTDT)
I SECPRNTDT=-1 S SECPRNTDT="" ;VSE-2396
Q SECPRNTDT
;
VALIDATESDCMT(ERRORS,SDCMT) ;Validate Comment
S SDCMT=$$CLEANCMMTS^SDES2APPTUTIL(SDCMT)
Q SDCMT
;
VALIDATEACCNUM(ERRORS,SDACC) ;Validate ACCESSION NUMBER
S SDACC=$G(SDACC,"")
S SDACC=$TR($G(SDACC),"^"," ")
Q SDACC
;
RETURNERROR(ERRORS,SDRECREQ,RETN,REQIEN) ;
M SDRECREQ=ERRORS
D SETEMPTYOBJ(.SDRECREQ,REQIEN)
D BUILDJSON^SDES2JSON(.RETN,.SDRECREQ)
Q
;
SETEMPTYOBJ(SDRECREQ,SDCREATE) ;Set the object to NULL
I SDCREATE="+1" S SDRECREQ("Request","IEN")="" Q
S SDRECREQ("Request","IEN")=""
Q
;
KEY(RECALLIEN) ;check that user has the correct SECURITY KEY
;INPUT:
; RECALLIEN - Pointer to RECALL REMINDERS file 403.5
;RETURN
; 0=User has the correct SECURITY KEY
; 135=error number - user does not have correct security keys
N KEY,KY,RET,SDPRV,SDFLAG
S RET=135
S (SDPRV,KEY,SDFLAG)="" S SDPRV=$P($G(^SD(403.5,+RECALLIEN,0)),U,5) D
.I SDPRV="" S RET=0
.I SDPRV'="" S KEY=$P($G(^SD(403.54,SDPRV,0)),U,7) D
..I KEY="" S RET=0 Q
..N VALUE
..S VALUE=$$LKUP^XPDKEY(KEY) K KY D OWNSKEY^XUSRB(.KY,VALUE)
..I $G(KY(0))'=0 S RET=0
Q RET
;
--- Routine Detail --- with STRUCTURED ROUTINE LISTING ---[H[J[2J[HSDES2RECLLREQ2 10213 printed Jul 22, 2026@16:03:26 Page 2
SDES2RECLLREQ2 ; ALB/MCB - VISTA SCHEDULING CREATE/EDIT RECALL REQUESTS 2 ; MAY 05, 2026
+1 ;;5.3;Scheduling;**944**;Aug 13, 1993;Build 2
+2 ;;Per VHA Directive 6402, this routine should not be modified
+3 ;
+4 ; Reference to DUZ^XUP is supported by IA #7487
+5 ;
+6 ;No Direct Call
QUIT
+7 ;
+8 ;
CREATERECREQ(RETN,SDCONTEXT,SDINPUT) ;SDES2 CREATE RECALL REQUEST 2
+1 NEW CAFDA,ERRORS,SDRECREQ,SDFDA,SDMSG,SDIEN,CAERR,REQUEST
+2 ; Newed the following to address variables leaking from external APIs/Functions
+3 NEW %,DG,DIC,DICR,DIW
+4 DO VALCONTEXT^SDES2VALCONTEXT(.ERRORS,.SDCONTEXT)
+5 IF $DATA(ERRORS)
SET ERRORS("Request","IEN")=""
DO BUILDJSON^SDES2JSON(.RETN,.ERRORS)
QUIT
+6 IF $GET(SDCONTEXT("USER DUZ"))'=""
NEW DUZ
DO DUZ^XUP(SDCONTEXT("USER DUZ"))
+7 SET SDINPUT("RECALL IEN")="+1"
+8 SET SDINPUT("DATE ENTERED")=$$VALIDATERCDTNTRD(.ERRORS,$GET(SDINPUT("DATE ENTERED")),SDINPUT("RECALL IEN"))
+9 DO VALIDATE(.ERRORS,.SDINPUT)
+10 IF $ORDER(ERRORS("Error",""))'=""
DO RETURNERROR(.ERRORS,.SDRECREQ,.RETN,SDINPUT("RECALL IEN"))
QUIT
+11 DO BLDREC(.SDFDA,.SDINPUT,.SDCONTEXT)
+12 DO UPDATE^DIE("","SDFDA","SDIEN","SDMSG")
KILL SDFDA
+13 IF $DATA(SDMSG)
DO ERRLOG^SDES2JSON(.ERRORS,134)
DO RETURNERROR(.ERRORS,.SDRECREQ,.RETN,SDINPUT("RECALL IEN"))
QUIT
+14 DO BLDCOMAUD(.CAFDA,.SDINPUT,SDIEN(1),"")
+15 if $DATA(CAFDA)
DO UPDATE^DIE("","CAFDA","","CAERR")
KILL CAFDA
+16 SET SDRECREQ("Request","IEN")=SDIEN(1)
+17 ;
+18 DO GETRECALL^SDES2GETRECALL(.REQUEST,SDIEN(1),SDINPUT("DFN"))
+19 IF $DATA(ERRORS)
MERGE ERRORS("Request","IEN")=REQUEST("Request","IEN")
DO BUILDJSON^SDES2JSON(.RETN,.ERRORS)
QUIT
+20 DO BUILDJSON^SDES2JSON(.RETN,.REQUEST)
+21 QUIT
+22 ;
+23 ;SDES2 EDIT RECALL REQUEST 2
UPDRECALLREQ(RETN,SDCONTEXT,SDINPUT) ;RECALLIEN,DFN,ACCNO,SDCMT,FASTING,APPTP,RRPROVIEN,CLINIEN,APPTLEN,DATE,RECPPDT,DAPTDT,USERIEN,SECPDT,EAS) ;update recall request
+1 NEW CAFDA,ERRORS,LASTNOTE,SDRECREQ,SDFDA,SDMSG,SDIEN,CAERR,REQUEST
+2 ; Newed the following to address variables leaking from external APIs/Functions
+3 NEW DG,DIC,DICR,DIW
+4 DO VALCONTEXT^SDES2VALCONTEXT(.ERRORS,.SDCONTEXT)
+5 IF $DATA(ERRORS)
SET ERRORS("Request","IEN")=""
DO BUILDJSON^SDES2JSON(.RETN,.ERRORS)
QUIT
+6 IF $GET(SDCONTEXT("USER DUZ"))'=""
NEW DUZ
DO DUZ^XUP(SDCONTEXT("USER DUZ"))
+7 DO VALIDATE(.ERRORS,.SDINPUT)
+8 IF $ORDER(ERRORS("Error",""))'=""
DO RETURNERROR(.ERRORS,.SDRECREQ,.RETN,SDINPUT("RECALL IEN"))
QUIT
+9 SET LASTNOTE=$$GET1^DIQ(403.5,SDINPUT("RECALL IEN")_",",2.5,"E")
+10 DO BLDREC(.SDFDA,.SDINPUT,.SDCONTEXT)
+11 DO FILE^DIE(,"SDFDA","SDMSG")
KILL SDFDA
+12 IF $DATA(SDMSG)
DO ERRLOG^SDES2JSON(.ERRORS,134)
DO RETURNERROR(.ERRORS,.SDRECREQ,.RETN,SDINPUT("RECALL IEN"))
QUIT
+13 DO BLDCOMAUD(.CAFDA,.SDINPUT,SDINPUT("RECALL IEN"),LASTNOTE)
+14 if $DATA(CAFDA)
DO UPDATE^DIE("","CAFDA","","CAERR")
KILL CAFDA
+15 SET SDRECREQ("Request","IEN")=SDINPUT("RECALL IEN")
+16 ;
+17 DO GETRECALL^SDES2GETRECALL(.REQUEST,SDINPUT("RECALL IEN"),SDINPUT("DFN"))
+18 IF $DATA(ERRORS)
MERGE ERRORS("Request","IEN")=REQUEST("Request","IEN")
DO BUILDJSON^SDES2JSON(.RETN,.ERRORS)
QUIT
+19 DO BUILDJSON^SDES2JSON(.RETN,.REQUEST)
+20 QUIT
+21 ;
BLDREC(SDFDA,SDINPUT,SDCONTEXT) ;build and file record
+1 NEW RECALLIEN
+2 SET RECALLIEN=SDINPUT("RECALL IEN")
+3 ;recall
SET SDFDA=$NAME(SDFDA(403.5,RECALLIEN_","))
+4 SET SDFDA(403.5,RECALLIEN_",",.01)=SDINPUT("DFN")
+5 if $GET(SDINPUT("ACCESSION NUMBER"))'=""
SET SDFDA(403.5,RECALLIEN_",",2)=$EXTRACT(SDINPUT("ACCESSION NUMBER"),1,25)
+6 if $GET(SDINPUT("COMMENT"))'=""
SET SDFDA(403.5,RECALLIEN_",",2.5)=$EXTRACT(SDINPUT("COMMENT"),1,80)
+7 SET SDFDA(403.5,RECALLIEN_",",2.6)=SDINPUT("FASTING")
+8 SET SDFDA(403.5,RECALLIEN_",",3)=SDINPUT("APPOINTMENT TYPE")
+9 SET SDFDA(403.5,RECALLIEN_",",4)=SDINPUT("RECALL PROVIDER IEN")
+10 SET SDFDA(403.5,RECALLIEN_",",4.5)=SDINPUT("CLINIC IEN")
+11 if SDINPUT("APPOINTMENT LENGTH")'=""
SET SDFDA(403.5,RECALLIEN_",",4.7)=SDINPUT("APPOINTMENT LENGTH")
+12 SET SDFDA(403.5,RECALLIEN_",",5)=SDINPUT("RECALL DATE")
+13 if $GET(SDINPUT("RECALL DATE PER PATIENT"))'=""
SET SDFDA(403.5,RECALLIEN_",",5.5)=SDINPUT("RECALL DATE PER PATIENT")
+14 if $GET(SDINPUT("DATE REMINDER SENT"))'=""
SET SDFDA(403.5,RECALLIEN_",",6)=SDINPUT("DATE REMINDER SENT")
+15 SET SDFDA(403.5,RECALLIEN_",",7)=DUZ
+16 ;only add if creating new record, cannot edit
if RECALLIEN="+1"
SET SDFDA(403.5,RECALLIEN_",",7.5)=SDINPUT("DATE ENTERED")
+17 if $GET(SDINPUT("SECOND PRINT DATE"))'=""
SET SDFDA(403.5,RECALLIEN_",",8)=SDINPUT("SECOND PRINT DATE")
+18 SET SDFDA(403.5,RECALLIEN_",",100)=$GET(SDCONTEXT("ACHERON AUDIT ID"))
+19 QUIT
+20 ;
BLDCOMAUD(CAFDA,SDINPUT,RECALLIEN,LASTNOTE) ;
+1 ; 403.57 COMMENT AUDIT multiple
+2 if '$LENGTH(SDINPUT("COMMENT"))
QUIT
+3 NEW LASTLENGTH,NEWLENGTH,NEWNOTE
+4 SET LASTLENGTH=$LENGTH(LASTNOTE)
SET NEWLENGTH=$LENGTH(SDINPUT("COMMENT"))
+5 SET NEWNOTE=$EXTRACT($EXTRACT(SDINPUT("COMMENT"),1,80),(LASTLENGTH+1),NEWLENGTH)
+6 if '$LENGTH(NEWNOTE)
QUIT
+7 SET CAFDA(403.57,"+1,"_RECALLIEN_",",.01)=$$NOW^XLFDT
+8 SET CAFDA(403.57,"+1,"_RECALLIEN_",",1)=DUZ
+9 SET CAFDA(403.57,"+1,"_RECALLIEN_",",2)=NEWNOTE
+10 QUIT
+11 ;
VALIDATE(ERRORS,SDINPUT) ;
+1 NEW OLDDFN
+2 SET OLDDFN=""
+3 SET SDINPUT("RECALL IEN")=$$VALIDATERECALIEN(.ERRORS,$GET(SDINPUT("RECALL IEN")))
+4 IF '$DATA(ERRORS)
IF SDINPUT("RECALL IEN")'="+1"
SET OLDDFN=$$GET1^DIQ(403.5,SDINPUT("RECALL IEN"),.01,"I")
+5 SET SDINPUT("DFN")=$$VALIDATEDFN(.ERRORS,$GET(SDINPUT("DFN")),OLDDFN)
+6 SET SDINPUT("FASTING")=$$VALIDATEFASTING(.ERRORS,$GET(SDINPUT("FASTING")))
+7 SET SDINPUT("APPOINTMENT TYPE")=$$VALIDATEAPPTP(.ERRORS,$GET(SDINPUT("APPOINTMENT TYPE")))
+8 SET SDINPUT("RECALL PROVIDER IEN")=$$VALIDATERRPRVIEN(.ERRORS,$GET(SDINPUT("RECALL PROVIDER IEN")))
+9 SET SDINPUT("CLINIC IEN")=$$VALIDATECLINIEN(.ERRORS,$GET(SDINPUT("CLINIC IEN")))
+10 SET SDINPUT("RECALL DATE")=$$VALIDATERECALLDT(.ERRORS,$GET(SDINPUT("RECALL DATE")))
+11 SET SDINPUT("APPOINTMENT LENGTH")=$$VALIDATEAPPTLEN(.ERRORS,$GET(SDINPUT("APPOINTMENT LENGTH")))
+12 SET SDINPUT("RECALL DATE PER PATIENT")=$$VALIDATERECPPDT(.ERRORS,$GET(SDINPUT("RECALL DATE PER PATIENT")))
+13 SET SDINPUT("DATE REMINDER SENT")=$$VALIDATEDAPTDT(.ERRORS,$GET(SDINPUT("DATE REMINDER SENT")))
+14 SET SDINPUT("SECOND PRINT DATE")=$$VALIDATESECPDT(.ERRORS,$GET(SDINPUT("SECOND PRINT DATE")))
+15 SET SDINPUT("COMMENT")=$$VALIDATESDCMT(.ERRORS,$GET(SDINPUT("COMMENT")))
+16 SET SDINPUT("ACCESSION NUMBER")=$$VALIDATEACCNUM(.ERRORS,$GET(SDINPUT("ACCESSION NUMBER")))
+17 QUIT
+18 ;
VALIDATERECALIEN(ERRORS,RECALLIEN) ;Validate Recall IEN
+1 IF $GET(RECALLIEN)=""
DO ERRLOG^SDES2JSON(.ERRORS,16)
QUIT RECALLIEN
+2 IF (RECALLIEN'="+1")&('$DATA(^SD(403.5,$GET(RECALLIEN))))
DO ERRLOG^SDES2JSON(.ERRORS,17)
QUIT RECALLIEN
+3 ;check that user has the correct security key
+4 IF $$KEY(RECALLIEN)>0
DO ERRLOG^SDES2JSON(.ERRORS,135)
+5 QUIT RECALLIEN
+6 ;
VALIDATEDFN(ERRORS,DFN,OLDDFN) ;Validate Patient DFN
+1 DO VALPATDFN^SDES2VAL2(.ERRORS,$GET(DFN),1)
+2 IF DFN'=""
IF OLDDFN'=""
IF DFN'=OLDDFN
DO ERRLOG^SDES2JSON(.ERRORS,2,"Patient ID on Recall doesn't match passed in Patient ID")
+3 QUIT DFN
+4 ;
VALIDATEFASTING(ERRORS,FASTING) ;Validate Fasting
+1 IF FASTING=""
DO ERRLOG^SDES2JSON(.ERRORS,141)
QUIT FASTING
+2 SET FASTING=$SELECT($$UP^XLFSTR(FASTING)="FASTING":"f",$$UP^XLFSTR(FASTING)="NON-FASTING":"n",$$UP^XLFSTR(FASTING)="F":"f",$$UP^XLFSTR(FASTING)="N":"n",FASTING="@":"@",1:138)
+3 IF FASTING=138
DO ERRLOG^SDES2JSON(.ERRORS,138)
+4 QUIT FASTING
+5 ;
VALIDATEAPPTP(ERRORS,APPTP) ;Validate Appointment Type from RECALL REMINDERS APPT TYPE (#403.51)
+1 IF APPTP=""
DO ERRLOG^SDES2JSON(.ERRORS,139)
QUIT APPTP
+2 SET APPTP=$ORDER(^SD(403.51,"B",APPTP,""))
+3 IF +APPTP
IF $DATA(^SD(403.51,APPTP,0))
QUIT APPTP
+4 IF +APPTP
IF '$DATA(^SD(403.51,APPTP,0))
DO ERRLOG^SDES2JSON(.ERRORS,132)
QUIT APPTP
+5 IF APPTP=""
DO ERRLOG^SDES2JSON(.ERRORS,139)
QUIT APPTP
+6 QUIT APPTP
+7 ;
VALIDATERRPRVIEN(ERRORS,RRPROVIEN) ;Validate Recall Provider IEN
+1 IF RRPROVIEN=""
DO ERRLOG^SDES2JSON(.ERRORS,137)
QUIT RRPROVIEN
+2 IF $GET(RRPROVIEN)'=""
IF '$DATA(^SD(403.54,RRPROVIEN))
DO ERRLOG^SDES2JSON(.ERRORS,131)
+3 QUIT RRPROVIEN
+4 ;
VALIDATECLINIEN(ERRORS,CLINIEN) ;Validate Clinic IEN
+1 IF CLINIEN=""
DO ERRLOG^SDES2JSON(.ERRORS,18)
QUIT CLINIEN
+2 IF CLINIEN'=""
IF '$DATA(^SC(CLINIEN))
DO ERRLOG^SDES2JSON(.ERRORS,19)
+3 QUIT CLINIEN
+4 ;
VALIDATERECALLDT(ERRORS,RECALLDATE) ;Validate Recall Date
+1 IF RECALLDATE=""
DO ERRLOG^SDES2JSON(.ERRORS,140)
QUIT RECALLDATE
+2 IF RECALLDATE'=""
SET RECALLDATE=$$ISOTFM^SDAMUTDT(RECALLDATE)
+3 IF RECALLDATE=-1
DO ERRLOG^SDES2JSON(.ERRORS,133)
+4 QUIT RECALLDATE
+5 ;
VALIDATERCDTNTRD(ERRORS,RECDTENTRD,RECALLIEN) ;Validate Recall Date Entered
+1 ; This is an IEN, so can't edit Recall Date Entered
IF RECALLIEN'="+1"
QUIT ""
+2 IF ($GET(RECDTENTRD)'="")
SET RECDTENTRD=$$ISOTFM^SDAMUTDT(RECDTENTRD)
+3 ;
IF (RECDTENTRD=-1)!(RECDTENTRD="")
SET RECDTENTRD=DT
+4 QUIT RECDTENTRD
+5 ;
VALIDATEAPPTLEN(ERRORS,LENGTHOFAPPT) ;Validate Length of Appointment
+1 SET LENGTHOFAPPT=$GET(LENGTHOFAPPT,"")
IF LENGTHOFAPPT=""
QUIT LENGTHOFAPPT
+2 IF '+LENGTHOFAPPT
DO ERRLOG^SDES2JSON(.ERRORS,116)
QUIT LENGTHOFAPPT
+3 IF LENGTHOFAPPT'=""
if ((+LENGTHOFAPPT<10)!(+LENGTHOFAPPT>240))
SET LENGTHOFAPPT=""
+4 QUIT LENGTHOFAPPT
+5 ;
VALIDATERECPPDT(ERRORS,RECPPTDT) ;Validate Recall Date Per Patient
+1 SET RECPPTDT=$GET(RECPPTDT,"")
SET RECPPTDT=$$ISOTFM^SDAMUTDT(RECPPTDT)
+2 ;VSE-2396
IF RECPPTDT=-1
SET RECPPTDT=""
+3 QUIT RECPPTDT
+4 ;
VALIDATEDAPTDT(ERRORS,DTRMSENT) ;Validate Date Reminder Sent
+1 SET DTRMSENT=$GET(DTRMSENT,"")
+2 SET DTRMSENT=$$ISOTFM^SDAMUTDT(DTRMSENT)
+3 ;VSE-2396
IF DTRMSENT=-1
SET DTRMSENT=""
+4 QUIT DTRMSENT
+5 ;
VALIDATESECPDT(ERRORS,SECPRNTDT) ;Validate Second Print Date
+1 SET SECPRNTDT=$GET(SECPRNTDT,"")
+2 IF SECPRNTDT'=""
SET SECPRNTDT=$$ISOTFM^SDAMUTDT(SECPRNTDT)
+3 ;VSE-2396
IF SECPRNTDT=-1
SET SECPRNTDT=""
+4 QUIT SECPRNTDT
+5 ;
VALIDATESDCMT(ERRORS,SDCMT) ;Validate Comment
+1 SET SDCMT=$$CLEANCMMTS^SDES2APPTUTIL(SDCMT)
+2 QUIT SDCMT
+3 ;
VALIDATEACCNUM(ERRORS,SDACC) ;Validate ACCESSION NUMBER
+1 SET SDACC=$GET(SDACC,"")
+2 SET SDACC=$TRANSLATE($GET(SDACC),"^"," ")
+3 QUIT SDACC
+4 ;
RETURNERROR(ERRORS,SDRECREQ,RETN,REQIEN) ;
+1 MERGE SDRECREQ=ERRORS
+2 DO SETEMPTYOBJ(.SDRECREQ,REQIEN)
+3 DO BUILDJSON^SDES2JSON(.RETN,.SDRECREQ)
+4 QUIT
+5 ;
SETEMPTYOBJ(SDRECREQ,SDCREATE) ;Set the object to NULL
+1 IF SDCREATE="+1"
SET SDRECREQ("Request","IEN")=""
QUIT
+2 SET SDRECREQ("Request","IEN")=""
+3 QUIT
+4 ;
KEY(RECALLIEN) ;check that user has the correct SECURITY KEY
+1 ;INPUT:
+2 ; RECALLIEN - Pointer to RECALL REMINDERS file 403.5
+3 ;RETURN
+4 ; 0=User has the correct SECURITY KEY
+5 ; 135=error number - user does not have correct security keys
+6 NEW KEY,KY,RET,SDPRV,SDFLAG
+7 SET RET=135
+8 SET (SDPRV,KEY,SDFLAG)=""
SET SDPRV=$PIECE($GET(^SD(403.5,+RECALLIEN,0)),U,5)
Begin DoDot:1
+9 IF SDPRV=""
SET RET=0
+10 IF SDPRV'=""
SET KEY=$PIECE($GET(^SD(403.54,SDPRV,0)),U,7)
Begin DoDot:2
+11 IF KEY=""
SET RET=0
QUIT
+12 NEW VALUE
+13 SET VALUE=$$LKUP^XPDKEY(KEY)
KILL KY
DO OWNSKEY^XUSRB(.KY,VALUE)
+14 IF $GET(KY(0))'=0
SET RET=0
End DoDot:2
End DoDot:1
+15 QUIT RET
+16 ;
