Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SDRPA02

SDRPA02.m

Go to the documentation of this file. 
  1. SDRPA02 ;bp-oifo/swo pait utils ; 9/10/04 9:33am
  1.  ;;5.3;Scheduling;**349,376**;AUG 13, 1993
  1.  Q       ;no entry from top
  1. DUP(RUNIEN,BATCHIDO) ;check for duplicate ACK response
  1.  ;RUNIEN     :  the ien in file 409.6 of the run
  1.  ;BATCHIDO   :  batchid pulled from the ACK message
  1.  ;V3         :  returns 0 if dup ACK or error and 1 new ACK
  1.  N V1,V2,V3,VNODE
  1.  S V3=0
  1.  I $G(RUNIEN)="" Q V3
  1.  I $G(BATCHIDO)="" Q V3
  1.  I $G(^SDWL(409.6,RUNIEN,2,0))="" Q V3
  1.  S V1=$O(^SDWL(409.6,RUNIEN,2,"B",BATCHIDO,"")) I V1="" Q V3
  1.  S VNODE=$G(^SDWL(409.6,RUNIEN,2,V1,0))
  1.  I $P(VNODE,"^")'=BATCHIDO Q V3
  1.  I $P(VNODE,"^",4)="" S V3=1
  1.  Q V3
  1. RSTAT ;check the status of the last run
  1.  ;V1     :  last run ien
  1.  ;VNODE  :  zero node of the run
  1.  ;ZTSK   :  the task number
  1.  N V1,V2,V3,VNODE,ZTSK
  1.  S V1=$O(^SDWL(409.6,999999999),-1) Q:'V1
  1.  S VNODE=$G(^SDWL(409.6,V1,0)) Q:VNODE=""
  1.  I $P(VNODE,"^",7) Q  ;the run has finished
  1.  S ZTSK=$P(VNODE,"^",2) Q:'ZTSK
  1.  D STAT^%ZTLOAD
  1.  I ZTSK(1)=1!(ZTSK(1)=2) Q  ;still running
  1.  ;S V2=$$RPAIT^SDRPA03(V1) ADD MESSAGE TO HELP DESK THAT TASK ERRORED
  1.  Q
  1. RUNCK() ;date check for run start
  1.  ;V1     :  ien file 19.2
  1.  ;V2     :  returns 0=do not run, 1=okay to run
  1.  ;V3     :  1st day of scheduling pattern
  1.  ;V4     :  2nd day of scheduling pattern
  1.  ;VNODE  :  zero node of 19.2
  1.  ;VDAY   :  current day plussed
  1.  ;run may be started on the 1st or 15th with a 3 day grace window
  1.  ;if no entry in 19.2 allow to run anytime
  1.  ;if scheduling pattern is not 1M(1,15) allow to run anytime
  1.  N V1,V2,V3,V4,VNODE,VDAY
  1.  S V2=0
  1.  S V1=$O(^DIC(19,"B","SD-PAIT TASKED TRANSMISSION","")) ;is the option scheduled?
  1.  S V1=$O(^DIC(19.2,"B",V1,""))
  1.  I V1="" S V2=1 D NSMSG Q V2  ;not scheduled, allow to run anytime
  1.  S VNODE=$G(^DIC(19.2,V1,0))
  1.  I VNODE="" S V2=1 Q V2  ;b xref, but no entry, allow to run anytime
  1.  I $P(VNODE,"^",6)'?1"1M("1.2N1","1.2N1")" S V2=1 D NSMSG Q V2  ;not our scheduling pattern, allow to run anytime
  1.  S V3=+$P($P($P(VNODE,"^",6),"(",2),",") ;1st date in month to run
  1.  S V4=+$P($P($P(VNODE,"^",6),",",2),")") ;2nd date in month to run
  1.  S VDAY=+$E($$DT^XLFDT(),6,7)
  1.  I VDAY'=V3,VDAY'=(V3+1),VDAY'=(V3+2),VDAY'=(V3+3),VDAY'=V4,VDAY'=(V4+1),VDAY'=(V4+2),VDAY'=(V4+3) D NRMSG Q V2
  1.  S V2=1
  1.  Q V2
  1. NRMSG ;no run message
  1.  N XMSUB,XMY,XMTEXT,XMDUZ,SDAMX,SDNOW,SDNAM
  1.  S XMSUB="PAIT Transmission"
  1.  S XMY("G.SD-PAIT")=""
  1.  S XMTEXT="SDAMX("
  1.  S XMDUZ="POSTMASTER"
  1.  S SDNOW=$$HTE^XLFDT($H,)
  1.  S SDNAM=$$GET1^DIQ(200,+$G(DUZ)_",",.01,"I")
  1.  S SDAMX(1)=SDNAM_" (DUZ="_DUZ_") attempted to start the PAIT transmission"
  1.  S SDAMX(2)="on "_SDNOW_", outside the authorized transmission dates."
  1.  S SDAMX(3)="The job has been cancelled"
  1.  D ^XMD
  1.  Q
  1. NSMSG ;non scheduled start-up
  1.  N XMSUB,XMY,XMTEXT,XMDUZ,SDAMX,SDNOW,SDNAM
  1.  S XMSUB="PAIT Transmission"
  1.  S XMY("G.SD-PAIT")=""
  1.  ;S XMY("VHACIONHD@DOMAIN.EXT")
  1.  S XMTEXT="SDAMX("
  1.  S XMDUZ="POSTMASTER"
  1.  S SDNOW=$$HTE^XLFDT($H,)
  1.  S SDNAM=$$GET1^DIQ(200,+$G(DUZ)_",",.01,"I")
  1.  S SDAMX(1)=SDNAM_" (DUZ="_DUZ_") started the PAIT transmission "
  1.  S SDAMX(2)="on "_SDNOW_".  Option SD-PAIT TASKED TRANSMISSION has no "
  1.  S SDAMX(3)="entry or an incorrect entry for scheduling frequency.  The correct frequency "
  1.  S SDAMX(4)="is 1M(1,15).  The National Help Desk has been notified to initiate a NOIS"
  1.  D ^XMD
  1.  Q